OpenOffice.info

Verfasst: **Sa, 05.09.2009 12:09**

Hallo,

ich habe zwei Tabellen, eine Referenz- (im Anhang) und eine Wertetabelle.
In einer Zelle der Wertetabelle werden zwei Zellen mit der Referenztabelle verglichen.
Anhand der eingegebenen Werte in der Wertetabelle werden diese mit den Ziffern 1-7 bewertet.

Die Formel schaut sich die Werte in der Wertetabelle an und bewertet diese durch die Informationen der Referenztabell mit den Zahlen von 1-7.

Meine Formel (zur besseren Übersicht untereinander geschrieben) funktioniert leider nicht so ganz bei der Bewertung 6.
Wobei ich vielleicht anstelle einer UND eine ODER Funktion nutzen sollte.

Aber hier erst mal meine Formel, mit der Frage ob man diese vielleicht verkürzen kann.

=WENN(ODER(ISTLEER($B6);ISTLEER($C6));"";
WENN(UND(ISTZAHL($B6);ISTZAHL($C6));
WENN(UND($B6>=$Grenzwerte.$C$14;$C6<=$Grenzwerte.$E$14);"7";
WENN(UND($B6<=$Grenzwerte.$C$8;$C6<=$Grenzwerte.$E$8);"1";
WENN(UND($B6<=$Grenzwerte.$C$9;$C6<=$Grenzwerte.$E$9);"2";
WENN(UND($B6<=$Grenzwerte.$C$10;$C6<=$Grenzwerte.$E$10);"3";
WENN(UND($B6<=$Grenzwerte.$C$11;$C6<=$Grenzwerte.$E$11);"4";
WENN(UND($B6<=$Grenzwerte.$C$12;$C6<=$Grenzwerte.$E$12);"5";
WENN(UND($B6>=$Grenzwerte.$C$13;$C6>=$Grenzwerte.$E$13);"6";
"0")))))))))

Das Problem ist ja das zwei Zellen der einen Tabelle mit zwei Zellen der Referenz Tabelle vergleichen werden müssen.
Da die Bewertung sich nach Systolischen und Diastolischen Wertbereichen orientiert.

MfG
mephisto2k

Verfasst: **Sa, 05.09.2009 14:04**

Hallo,

seh ich das richtig, für die Bewertungszahl zählt der höchste Wert der Bewertung? Dan könntest Du es so machen, wie ich es in der Beispieldatei aufgebaut hab.

Der SVerweis ohne 4. Parameter sucht sich den jeweils entsprechenden Wert aus der ansteigenden Wertetabelle (wichtig ist noch die Zeile mit den Nullwerten, damit der Sverweis Werte kleiner 120:80 auch abarbeiten kann). Die Ergebnisse der zwei SVerweise für systolisch und diastolisch gehen dann in die Max()-Formel rein und spucken Dir den höheren der beiden Werte wieder aus.

Was ich aber nicht versteh, ist die letzte Zeile Deiner Bewertung mit der isolierte systolische Hypertonie und dem Wert 140:90. Soll das nur dann eintreten? Oder wie ist das gedacht?

In der Datei stehen die einzelnen SVerweise in den Zellen G21 und H21 nur zur Kontrolle und Veranschaulichung drin. Die Bewertung läuft nur in E21.

Viele Grüße
AhQ

Verfasst: **Sa, 05.09.2009 14:28**

Hi

und Danke schon mal

ich hatte alle Formatierungen gelöscht da ist mir wohl bei der isolierten Hypertonie ein Fehler unterlaufen
Sie tritt ein wenn: sys >= 140 und dia <= 90

ich kann mir deinen Beitrag aber wohl erst Sonntag richtig anschauen
dann melde ich mich nochmal

MfG
mephisto2k

Verfasst: **Sa, 05.09.2009 14:36**

Hallo AhQ,

ich bin auch momentan etwas am rumknobeln, komme aber noch nicht so richtig in fahrt.

Was ich aber nicht versteh, ist die letzte Zeile Deiner Bewertung mit der isolierte systolische Hypertonie und dem Wert 140:90. Soll das nur dann eintreten? Oder wie ist das gedacht?

Schau mal hier in seine erste Beispieldatei rein. Aber ich greife das schon mal vorweg auf.
Das ist ein Sonderfall, für sie gelten ganz andere Bedingungen.

Code: Alles auswählen

systolisch	diastolisch	
> 140		< 90

Das bedeutet, dass der Systolische Wert größer als 140, UND der diastolische Wert kleiner als 90 sein muss um eine "isolierte systolische Hypertonie" zu sein. Als Zahlenbeispiel würde das dann so aussehen.
141 : 88

Wenn jedoch folgende Werte gemessen werden,
141 : 91
dann ist es eine "leichte Hypertonie (Schweregrad 1)", und keine isolierte.

Vorausgesetzt das ich es nicht fehlinterpretiere.

Ich glaube aber daran, dass Du das aktuelle Problem schneller in den Griff bekommst, als ich

Gruß
balu

Verfasst: **Sa, 05.09.2009 17:17**

Hallo,

mephisto2k hat geschrieben:Sie tritt ein wenn: sys >= 140 und dia <= 90

balu hat geschrieben:Das ist ein Sonderfall, für sie gelten ganz andere Bedingungen.

keine uninteressante Information...

Dann fangen wir halt diese Möglichkeit (Systole >=140, Diastole <=90) einfach mit einer Wenn()-Formel auf etwa in diesem Sinne (in E20, B20 und C20 sind in meiner Beispieldatei Systole bzw. Diastole):

=WENN(UND(B20>=140;C20<=90);"isolierten systolische Hypertonie";MAX(SVERWEIS(B20;$C$8:$G$15;5);SVERWEIS(C20;$E$8:$G$15;3)))

Viele Grüße
AhQ

Verfasst: **Mo, 26.04.2010 19:12**

Hallo

Code: Alles auswählen

=SVERWEIS(B63;$B$76:$D$125;3;0)

erfüllt kurz und bündig die Aufgabenstellung

Deine zweite Frage solltest evtl noch mal etwas verständlicher erklären, vielleicht ist '-->Daten-->Gültigkeit--(Liste oder Zellbereich)'
daß was du suchst.

Gruß Karo

Verfasst: **Mo, 26.04.2010 20:06**

Hallo
Vergiss die Formularsteuerelemente und beschäftige dich stattdessen mit -->Daten-->Gültigkeit-->'Kriterien'-Zulassen: |Zellbereich|

Gruß Karo

Verfasst: **Mo, 26.04.2010 20:21**

Hallo

Ja hatte ich auch schon aber gefällt mir nicht. Zumal wenn man in eine andere Zelle geht dann ist der DropDown pfeil weg.

Ja und - wenn du in einer anderen Zelle bist, brauchst du doch den DropDown momentan nicht.

Gruß Karo

Verfasst: **Mo, 26.04.2010 21:29**

Ich nochmal

hab mich mal hier im forum angemeldet

Bräuchte nochmal hilfe. Hab 0,00 ahnung vom =SVERWEIS -.-
Habe es versucht aber irgendwie kommen bei mir ganz falsche zahlen raus

Hoffe ihr könnt mir nochmals helfen bzw den sverweis zukommen lassen

=WENN(B66=D76;E76;WENN(B66=D77;E77;WENN(B66=D78;E78))) je bis 125

=WENN(B66=F76;G76;WENN(B66=F77;G77;WENN(B66=F78;G78;WENN(B66=F79;G79)))) je bis 125

=WENN(G66=L76;M76;WENN(G66=L77;M77;WENN(G66=L78;M78;WENN(G66=L79;M79)))) je bis 125

=WENN(G66=L76;N76;WENN(G66=L77;N77;WENN(G66=L78;N78;WENN(G66=L79;N79)))) je bis 125

Hab mal die Datei hochgeladen.

GRUß

Verfasst: **Mo, 26.04.2010 22:53**

Hallo
Ich erklärs dir jetzt nach dem Beispiel:

=WENN(B66=D76;E76;WENN(B66=D77;E77;WENN(B66=D78;E78))) je bis 125

=SVERWEIS( B66 ; D76:E125 ; 2 ; 0)
die Formel sucht in der ersten Spalte des Bereichs D76:E125 nach im Inhalt von B66
und gibt an der Fundstelle den Inhalt aus der Spalte 2 des Bereichs D76:E125 zurück.

Gruß Karo

Verfasst: **Mo, 26.04.2010 23:45**

Karolus hat geschrieben:Hallo
Ich erklärs dir jetzt nach dem Beispiel:
=WENN(B66=D76;E76;WENN(B66=D77;E77;WENN(B66=D78;E78))) je bis 125
=SVERWEIS( B66 ; D76:E125 ; 2 ; 0)
die Formel sucht in der ersten Spalte des Bereichs D76:E125 nach im Inhalt von B66
und gibt an der Fundstelle den Inhalt aus der Spalte 2 des Bereichs D76:E125 zurück.

Gruß Karo

Habe die Formel so geschrieben: =SVERWEIS(B66;$D$76:$E$125;2;0) und einmal so: =SVERWEIS(B66;D76:E125;2;0) ......
beidemale hat es leider nicht geklappt.
Es kam genau das selbe wie mit der WENN formel. Nur das Problem ist das diverse Quest´s zb. Karotten braucht aber unterschiedliche mengen.

http://img11.imageshack.us/img11/6718/11111rs.jpg

Beispiel: Bei Quest 1 braucht man 45 Karotten und bei Quest 4 sind es 672 Karotten.
Mit der Formel kommt bei Quest 4 - 45 Karotten.

gruß

EDIT: Habe die Doppelten Artikel pro Spattel mit zahlen versehen. So funktioniert es einwandfrei. oder vielleicht hat ja wer ne Idee wie es gehen könnte ohne zahlen dahinter.

Verfasst: **Di, 27.04.2010 00:31**

Hallo tk,

Bräuchte nochmal hilfe. Hab 0,00 ahnung vom =SVERWEIS -.-

Immer wieder empfehlenswerte Lektüre ist die OOo Online-Hilfe (F1), und natürlich das Wiki: DatenFinden (SVERWEIS)

Karotten braucht aber unterschiedliche mengen.

[...]

Bei Quest 1 braucht man 45 Karotten und bei Quest 4 sind es 672 Karotten.
Mit der Formel kommt bei Quest 4 - 45 Karotten.

Das liegt daran, dass in der Spalte "Artikel" der Suchbegriff "Karotten" mehrfach vorkommt. Auch deshalb im Wiki-Link nachlesen.
Das bedeutet aber auch, dass Du dein System ergänzen (ausbauen) musst damit die Formeln wissen aus welchen Zutaten und in welchen Mengen ein Endprodukt besteht. Denn weder die SVERWEIS-Formel, noch wir wissen das.

aber wenn die Tabelle fertig und bereit zum Verschicken ist, dann benötige ich die wieder.
Und da bleibt das problem ja bestehen das sich die teile umstellen.

Gib bitte bescheid, ob sich die DropDowns in T32 und in D52:E53 verstellt haben, denn die habe ich in der geänderten Datei auf "Der ausgewählte Eintrag" eingestellt.

Ich habe mal einige Formeln vereinfacht, und die dementsprechenden Zellen und Spalten Farblich markiert (dicker Blauer Rahmen, Gelber Hintergrund, Rote Schrift). Als eine geänderte Formel nehme ich diese als Beispiel.

Code: Alles auswählen

=WENN(C6+D6+E6+F6+G6+H6+I6+J6<B6;0;WENN(C6+D6+E6+F6+G6+H6+I6+J6=B6;0;WENN(C6+D6+E6+F6+G6+H6+I6+J6>B6;C6+D6+E6+F6+G6+H6+I6+J6-B6)))

Und habe das daraus gemacht:

Code: Alles auswählen

=WENN(SUMME(C6:J6)>B6;SUMME(C6:J6)-B6;0)

Du solltest dich doch noch mal mit der Logik einer WENN-DANN-SONST Formel vertraut machen.
Deine Formel prüft erst ob die Summe kleiner B6 ist (<B6), dann ob die Summe gleich B6 (=B6) und in beiden Fällen soll eine 0 ausgegeben werden, wenn die Bedingung erfüllt ist. Wenn aber die Summe größer B6 ist (>B6), dann soll von der Summe B6 (-B6) subtrahiert werden. Und dieses Verfahren ist einfach überflüssig!

Denn die Logik der WENN-DANN-SONST Formel besagt ja; WENN das zu überprüfende Ereignis zutrifft, DANN mache dieses, SONST mach jenes.
Also WENN die Summe von C6 bis J6 größer als B6 ist, DANN ziehe von der Summe B6 ab.
WENN die Summe von C6 bis J6 NICHT größer als B6 ist, dann gib eine 0 aus (SONST).
Und das NICHT bedeutet jetzt in diesem Falle: Die Summe ist entweder gleich, oder aber kleiner als B6.

Sie erfüllt also nicht das zu überprüfende Ereignis von größer B6 (>B6). Da also die Ereignisprüfung NICHT zutrifft, macht die Formel mit der SONST-Bedingung weiter und gibt die 0 aus.

Ich hoffe Du verstehst mich

Gruß
bal

Verfasst: **Di, 27.04.2010 08:11**

Hallo

Balu hat geschrieben:Als eine geänderte Formel nehme ich diese als Beispiel.
Code: Alles auswählen
=WENN(C6+D6+E6+F6+G6+H6+I6+J6<B6;0;WENN(C6+D6+E6+F6+G6+H6+I6+J6=B6;0;WENN(C6+D6+E6+F6+G6+H6+I6+J6>B6;C6+D6+E6+F6+G6+H6+I6+J6-B6)))
Und habe das daraus gemacht:
Code: Alles auswählen
=WENN(SUMME(C6:J6)>B6;SUMME(C6:J6)-B6;0)

Diesen Fall kann man auch abhandeln mit:

Code: Alles auswählen

=MAX(SUMME(C6:J6)-B6;0)

Gruß Karo

Verfasst: **Di, 27.04.2010 09:09**

Gib bitte bescheid, ob sich die DropDowns in T32 und in D52:E53 verstellt haben, denn die habe ich in der geänderten Datei auf "Der ausgewählte Eintrag" eingestellt.

Also verschoben haben sich deine DropDown´s nicht.
Nur wenn ich bei dir etwas daraus wähle kommt leider auch kein ergebniss.

=wenn(summe(c6:j6)>B6;summe(c6:j6)-B6:0)

Habe diese Formel mal bei mir verwendet, aber wenn ich mehr benötige als ich habe dann kommt Err:522.

=MAX(SUMME(C6:J6)-B6;0)

Diese Formel funktioniert und werde Sie auch verwenden. Schön kurz und kompackt

Nun nochmals zu meinen DropDown´s. (ewiges thema

)
Warum verstellen die sich bei mir immer, bzw weiß einer eine lösung?
Habe schon in der Hilfe gesucht aber ncihts gefunden.

gruß

Verfasst: **Di, 27.04.2010 12:10**

Hallo Miteinander,

@tk1982

Also verschoben haben sich deine DropDown´s nicht.

Ja okay. Nur das wollte ich nicht wissen.
Mich interessierte es vielmehr, ob sich die genannte Eigenschaft des DropDowns geändert hat.

Nur wenn ich bei dir etwas daraus wähle kommt leider auch kein ergebniss.

Das kann ich mit T32 {für Bauplatz} hier nicht bestätigen. Egal ob ich in OOo, oder in Go-oo teste, so bald ich dort etwas auswähle ändern sich in R34 und R36 die dortigen Werte. Also funktioniert es.

aber wenn die Tabelle fertig und bereit zum Verschicken ist, dann benötige ich die wieder.
Und da bleibt das problem ja bestehen das sich die teile umstellen.

Jedoch funktioniert es nicht, wenn die Datei als Excel-Datei gespeichert wurde und dort geöffnet wird.

Also beantworte jetzt bitte folgendes:
- Betriebssystem?
- OOo-Version?
- Datei austausch zwischen OOo und Excel?

Und ferner bitte ich dich darum, wegen des DropDowns einen neuen Thread zu eröffnen. Ist halt übersichtlicher.

@Karo
Ja ja! Is schon klar, dass Du natürlich mal wieder toppen musstest

. Aber in anbetracht des Threads hier war mein Vorschlag schon passend, gelle

.

Gruß
balu

OpenOffice.info

Vereinfachen einer WENN Funktion

Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion

Re: Vereinfachen einer WENN Funktion