OpenOffice.info

Code: Alles auswählen

Function fncPathCorrected(sPath as String) as String 'Function to ensure slash or backslash at the end of string

	Dim iPos as Integer
	Dim sLastCharacter as String
	
	sLastCharacter = Right(sPath,1)
	iPos = InStr(sPath, "/")
	
	If iPos = 0 Then 'it's a Windows path
		If sLastCharacter <> "\" Then 'backslash is missing
			sPath = sPath & "\"
		End If
	Else 'it's a Linux path
		If sLastCharacter <> "/" Then 'slash is missing
			sPath = sPath & "/"
		End If
	End If
	
	fncPathCorrected = sPath	

End Function

Code: Alles auswählen

    sDirectory = fncPathCorrected(objBlatt.getCellRangeByName("N3").String)

Code: Alles auswählen

Sub Slash_Backslash
REM 1 = Windows _ 3 = MacOS _ 4 = Unix
	OS = GetGUIType()
	if OS = 1 then sStrich = "\" REM Windows
	if OS = 4 then sStrich = "/" REM Unix / MacOS 
	print sStrich 
end sub

Code: Alles auswählen

Sub Main
print getpathseparator 'Pfadtrenner des aktiven Betriebssystems
End Sub

Code: Alles auswählen

REM  *****  BASIC  *****
option explicit

REM XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
REM XX       Macro : Zum erzeugen von PDF-Dateien      XX
REM XX        erstellt am : 21.12.2012                 XX
REM XX          Autoren : boser, F3K Total             XX
REM XX                                                 XX
REM XX   Hinweise auf dem Tabellblatt "PDF" beachten   XX
REM XX                                                 XX
REM XX          Version : 0.1? ( Testversion )         XX
REM XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX

Sub PDF_Dateien_erzeugen
	Dim objDatei as Object
	Dim objBlaetter as Object
	Dim objBlatt as Object
	Dim objZelle as Object
	dim objCursor as Object
	Dim objExportBlatt as Object
	Dim sRangename as String
	dim oRange as Object
    dim oRanges(0) as Object
	Dim sDirectory as String
	Dim sZellwertN4 as String
	Dim i as Integer
	Dim j as integer     rem Tabellblattnummer
	Dim intZeilen as Integer
	Dim strTab as String
	Dim von as String
	Dim bis as String
	Dim sURL as String
	Dim myProps(0) as New com.sun.star.beans.PropertyValue

	
	objDatei = ThisComponent
	objBlaetter = objDatei.Sheets
	objBlatt = objBlaetter.getByName("PDF")

	objZelle = objBlatt.getCellRangebyName("A1")	
	objCursor = objBlatt.createCursorByRange(objZelle)
	objCursor.collapseToCurrentRegion()
	intZeilen = objCursor.Rows.Count

	For i = 2 to intZeilen-1
		objZelle = objBlatt.getCellByPosition(0, i)
		strTab = objZelle.String
		objZelle = objBlatt.getCellByPosition(1, i)
		von = objZelle.String
		objZelle = objBlatt.getCellByPosition(3, i)
		von = von & objZelle.VALUE
		objZelle = objBlatt.getCellByPosition(2, i)
		bis = objZelle.String
		objZelle = objBlatt.getCellByPosition(4, i)
		bis = bis & objZelle.VALUE

		sRangename = von & ":" & bis
        objExportBlatt = objBlaetter.getbyname(strTab)
        oRange = objExportBlatt.getCellRangeByName(sRangename)

        'Druckbereich setzen
        oRanges(0) = oRange.RangeAddress
        objExportBlatt.setprintAreas(oRanges())
        sDirectory = objBlatt.getCellRangeByName("N3").String
        sZellwertN4 = objBlatt.getCellRangeByName("N4").String
        sURL = converttourl(sDirectory & sZellwertN4 & "_" & strTab & ".pdf")'passt den Pfad dem Betriebssystem an
        'PDF exportieren
        myProps(0).Name="FilterName"
        myProps(0).Value = "calc_pdf_Export"
        objDatei.storetoUrl(sURL,myProps())
        objExportBlatt.setprintAreas(array())'Druckbereich löschen
   next i

	msgbox "Ende"
End Sub