OpenOffice.info

Code: Alles auswählen

SUB Datenbankbackup
	REM Von der Datenbankdatei *.odb wird eine Kopie in das Backup-Verzeichnis erstellt. 
	REM Die Maximalzahl an Kopien ist auf 5 Kopien eingestellt. Anschließend wird die älteste Kopie ersetzt.
	REM Dieses Verfahren deckt nicht ab:
	REM - Dateneingaben, die bei bereits geöffneter Datenbank gemacht werden, da die Daten erst beim Schließen der Datei in die *.odb-Datei geschrieben werden.
	REM Siehe dazu die Prozedur "Daten_aus_Cache_schreiben"
	DIM oPath AS OBJECT
	DIM oDoc AS OBJECT
	DIM sTitel AS STRING
	DIM sUrl_Ziel AS STRING
	DIM sUrl_Start AS STRING
	DIM i AS INTEGER
	DIM k AS INTEGER
	oDoc = ThisComponent
	sTitel = oDoc.Title	'Name des Dokumentes, z.B. Medien_mit_Makros.odb'
	sUrl_Start = oDoc.URL	'Pfad zu dem Titel'
	oPath = createUnoService("com.sun.star.util.PathSettings")
	FOR i = 1 TO 6
		IF NOT FileExists(oPath.Backup & "/" & i & "_" & sTitel) THEN
		REM Im Backup-Verzeichnis des Datenbanknutzers von LO wird gespeichert, und zwar beginnend mit der Nummer, gefolgt durch einen Unterstrich und weiter mit dem ursprünglichen Titel.
			IF i > 5 THEN	
			REM Wenn i größer als 5 wird existieren bereits 5 Sicherheitskopien. Jetzt muss nachgesehen werden, welche Kopie die älteste ist, um diese zu ersetzen.
				FOR k = 4 TO 1 STEP -1
					IF FileDateTime(oPath.Backup & "/" & k & "_" & sTitel) <=  FileDateTime(oPath.Backup & "/" & k+1 & "_" & sTitel) THEN
					REM Die Datei mit der Nummer 4 muss auf vor der mit der Nummer 5 erstellt worden sein. Ist dies der Fall, so wird weiter gesucht.
					REM Die Suche beginnt also bei 4 und wird abwärts fortgesetzt, immer im direkten Vergleich mit der nächst höheren Ziffer.
					REM Ist 1 erreicht und immer noch vor 2 erstellt worden, so wird 1 ersetzt.
						IF k = 1 THEN
							i = k
							EXIT FOR
						END IF
					ELSE
					REM ist eine Zahl erreicht worden, bei der die Datei mit der höheren Nummer älter ist als die Datei mit der niedrigeren Nummer, so wird die Datei mit der höheren Nummer ersetzt.
						i = k+1
						EXIT FOR
					END IF
				NEXT
			END IF
			EXIT FOR
		END IF
	NEXT
	sUrl_Ziel = oPath.Backup & "/" & i &"_" & sTitel
	REM Der Pfad für die Zieldatei wird festgelegt und das Dokument zur Zieldatei hin kopiert.
	FileCopy(sUrl_Start,sUrl_Ziel)
END SUB

SUB Daten_aus_Cache_schreiben
	REM Schreibt die Daten aus der Tabelle auch während der Laufzeit von Base direkt auf die Platte.
	DIM oDaten AS OBJECT
	DIM oDataSource AS OBJECT
	oDaten = ThisDatabaseDocument.CurrentController
	IF NOT ( oDaten.isConnected() ) THEN oDaten.connect()
	oDataSource = oDaten.DataSource
	oDataSource.flush
END SUB

SUB Backup_sofort
	Daten_aus_Cache_schreiben
	Datenbankbackup
END SUB

Code: Alles auswählen

oDoc = ThisComponent

Code: Alles auswählen

.flush