OpenOffice.info

Code: Alles auswählen

SUB Zwischenablage
	DIM oDoc AS OBJECT
	DIM oDrawpage AS OBJECT
	DIM oForm AS OBJECT
	DIM oFeld AS OBJECT
	DIM sClipBoard AS STRING
	DIM a()
	oDoc=thisComponent	
	oDrawpage=oDoc.Drawpage
	REM Lage des Feldes in dem entsprechenden Formular aufsuchen
	oForm=oDrawpage.Forms.getByName("Formular")
	oFeld=oForm.getByName("Datum")
	sClipBoard = GetClipboard
	IF sClipboard = "" THEN
		sClipBoard = "Keine Daten in der Zwischenablage enthalten!"	
		msgbox sClipBoard
	ELSE
		a = split(sClipBoard,".")
		IF Ubound(a)<> 2 THEN
			sClipBoard = "Keine gültige Datumseingabe!"	
			msgbox sClipBoard
		ELSE
			unoDate = createUnoStruct("com.sun.star.util.Date")
			IF len(a(0))= 1 THEN
				a(0) = "0"+a(0)
			END IF
			unoDate.Day = a(0)
			IF len(a(1))= 1 THEN
				a(1) = "0"+a(1)
			END IF
			unoDate.Month = a(1)
			IF len(a(2))= 0 THEN
				unoDate.Year = Year(Date)
			ELSEIF len(a(2)) = 2 THEN
				unoDate.Year = "20"+a(2)
			ELSE
				unoDate.Year = a(2)
			END IF
			oFeld.BoundField.updateDate(unoDate)	
		END IF
	END IF
END SUB


FUNCTION GetClipboard
	On Error goto ErrorHandler
	DIM ClipBoardHandle AS OBJECT
	DIM DataObj AS OBJECT
	DIM DataTypSeq() AS OBJECT
	DIM sClipBoardString AS STRING	
	ClipBoardHandle = createUnoService("com.sun.star.datatransfer.clipboard.SystemClipboard")
	DataObj = createUnoService("com.sun.star.datatransfer.XTransferable")
	DataObj = ClipBoardHandle.getContents()
	DataTypSeq = DataObj.getTransferDataFlavors()
	sClipBoardString = DataObj.getTransferData(DataTypSeq(0))
	getClipboard = sClipBoardString
	EXIT FUNCTION	
		ErrorHandler:	
		GetClipboard = ""	
END FUNCTION