Verständnisproblem bei verschachtelten Operatoren

Das Tabellenkalkulationsprogramm

Moderator: Moderatoren

fratso
Beiträge: 4
Registriert: Mo, 14.05.2018 16:34

Verständnisproblem bei verschachtelten Operatoren

Beitrag von fratso » Mo, 14.05.2018 16:47

Moin!

Ich versuche, folgende Zeilen in eine zu packen; leider mit mäßigem Erfolg.

=WENN(I83="ganz_oben";"-";"")
=WENN(UND(H83=0;G83>=0,5);"oben";"")
=WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";"")
=WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";"")

Weiß hier jemand Rat?

Gruß

Frank

Mondblatt24
*****
Beiträge: 266
Registriert: So, 14.05.2017 16:11

Re: Verständnisproblem bei verschachtelten Operatoren

Beitrag von Mondblatt24 » Mo, 14.05.2018 17:20

Hallo,

Code: Alles auswählen

WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))

Gruß Peter
Win.10(x64)__ LO 6.0.7(x64); AOO Portable 4.1.5
Fragen, die zur Zufriedenheit beantwortet wurden, sollten im Betreff des Eröffnungspost mit dem Zusatz [GELÖST] versehen werden.

Benutzeravatar
lorbass
********
Beiträge: 4116
Registriert: Mo, 01.05.2006 21:29
Wohnort: Bonn

Re: Verständnisproblem bei verschachtelten Operatoren

Beitrag von lorbass » Mo, 14.05.2018 17:46

Bei derartigen Gelegenheiten gehe ich etwa so vor:

Im ersten Schritt kopiere ich deine Formeln in eine Textdatei, die ich mit 'nem normelane Text-Editor bearbeiten kann. Dort bringe ich ein bisschen Struktur in die WENN-Formel:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  ""
)
WENN(UND(H83=0;G83>=0,5);
  "oben";
  ""
)
WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
  "fast_unten";
  ""
)
WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
  "ganz_unten";
  ""
)
Danach ersetze die leere Zeichenkette (»""«) im SONST-Zweig durch die komplette nächste WENN-Funktion:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  WENN(UND(H83=0;G83>=0,5);
    "oben";
    WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
      "fast_unten";
      WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
        "ganz_unten";
        ""
      )
    )
  )
)
Das kann ich dann so, wie's dasteht, in eine Calc-Zelle kopieren. Alternativ kann ich die Struktur wieder rausnehmen und die Formel als eine einzige Zeile nach Calc transportieren:

Code: Alles auswählen

=WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))
Um die Logik das Ganzen hab ich mich hier allerdings nicht gekümmert, weil ich keinen blassen Schimmer davon habe, was in den diversen Zellen steht und was in welchem Fall als Ergbnis rauskommen soll.

Gruß
lorbass

fratso
Beiträge: 4
Registriert: Mo, 14.05.2018 16:34

Re: Verständnisproblem bei verschachtelten Operatoren

Beitrag von fratso » Mo, 14.05.2018 18:30

Aufgabe gelöst! Ich danke herzlich für die beiden schnellen Antworten.

Frank

Antworten