OpenOffice.info

An alle die gepostet haben - super vielen Dank für euere Beiträge - die haben mich wirklich weiter gebracht und die erwünschte Lösung wurde erzielt.

Greets
Dropdown

[quote="Sanne"]Die Alternative dazu in OO wäre eigentlich die Funktion "SUMMENPRODUKT:
=SUMMENPRODUKT($C$1:$C$65000;$A$1:$A$65000="Offen";$D$1:$D$65000>=01.01.09;$D$1:$D$10<=31.01.09)

@Sanne - die Lösung ist genial - vielen Dank, das hätte mich ansonsten wahrscheinlich Wochen gekostet.

Ich stelle grad in meiner OO-Version (2.4.3) fest, dass die Datumsangabe bei mir nicht verarbeitet wird. Ist das nur bei mir so oder kann das noch jemand nachvollziehen?
Wenn ich die Datumsangabe auslagere:
E1: 01.01.09
E2: 31.01.09
dann funktioniert die Formel so:
=SUMMENPRODUKT($C$1:$C$65000;$A$1:$A$65000="Offen";$D$1:$D$65000>=E1;$D$1:$D$65000<=E2)
Schreibe ich das Datum jedoch direkt in die Formel, dann macht OO das daraus:
=SUMMENPRODUKT($C$1:$C$65000;$A$1:$A$65000="Offen";$D$1:$D$65000>=01.010.09;$D$1:$D$65000<=31.010.09)

mfG

@EDIT
Habe das Gleiche grad mit 2.3 und mit 3.1 versucht und da sieht es gleich aus, eine Datumseingabe wird hier nicht akzeptiert. Lediglich dieser Umweg über ein Textformat war möglich:
=SUMMENPRODUKT($C$1:$C$10;$A$1:$A$10="Offen";$D$1:$D$10>=DATWERT("01.01.09");$D$1:$D$10<=DATWERT("31.01.09"))[/quote]

Grüzi Sanne,

[quote="Sanne"]
Dass die Zellbereiche gleich gross sein müssen, weiss ich und ist bei mir auch so.
Das habe ich hier nur falsch reinkopiert,
[/quote]
Okay,ein Problem weniger.

[quote="Sanne"]
Aber wenn Du Dir das Datum ansiehst, dann ist da eine 0 zuviel beim Monat.
[/quote]
Yep! Das hatte ich beim lesen wohl gesehen, aber hinterher beim Formel erstellen nicht mehr dran gedacht.

[quote="Sanne"]
Es verträgt sich nicht mit dem Gebietsschema "Schweiz". Wenn ich umstelle auf "Deutschland", geht's.
[/quote]
Ei da dautz!
Du hast Recht!
Ich habe mal eben in der 2.2.1 auch auf Schweiz ungestellt und es wurde dann der Monat auch mit einer zusätzlichen 0 versehen. Also aus 01.01.09 wurde in der Formel dann 01.010.09. Komisch ist es schon, aber gut zu wissen. Erst hatte ich noch gedacht das dies ein Linux Problem ist, aber dank deiner Beobachtung wissen wir nun das dies ein Gebietsschema Problem ist. Nur warum und wieso, keine Ahnunhg.


Gruß
balu

Hallo zusammen,
[b]MS-Excel verfügt über keine Funktion "SUMMEWENN[color=#FF0000]S[/color]" hat wohl aber die Funktion "SUMMEWENN"[/b]
welche auch in "Ooo_Calc" zur Verfügung steht.
Wundert mich, das dies keiner erkannt hat.

mfg
Gert

=DATUM($A$1;1;1)

=DATUM($A$1;MONAT(F2)+1;1)

=SUMMENPRODUKT($C$3:$C$11;$A$3:$A$11=$E3;MONAT($D$3:$D$11)=MONAT(F$2))

Hallo Leute,

@Sanne
SUMMENPRODUKT mag keine Unterschiedlich lange Zellbereiche, das stößt SUMMENPRODUKT sauer auf. Wenn Du in deiner Formel beispielsweise den Zellbereich von $D$1:$D$10 auf $D$1:$D$65000 änderst, so das alle gleich lang sind, dann funzt auch die Formel. Nur mit den kleinen Unterschied, dass aus 01.01.09 automatisch 39814 wird. Was aber wohl nicht so sehr dramatisch ist.


@Dropdown
Auch wenn Excel 2007 SUMMEWENNS hat, so ist deine Formel doch etwas ungeschickt aufgebaut da sie eine starre Formel ist. Meiner Meinung nach würde es besser sein, wenn Du sie Flexibel machen würdest. Das würde in etwa so aussehen.

In A1 das Jahr eingeben, in vierstelliger schreibweise. Also einfach 2009.
In der Zeile 2 hast Du z.B. Status Nummer Betrag stehen.
In der Zeile 2 ab Spalte F schreibst Du nicht einfach Jan, sondern folgende Formel.
[code]
=DATUM($A$1;1;1)
[/code]und in G2 folgende Formel.
[code]
=DATUM($A$1;MONAT(F2)+1;1)
[/code]
Nun formatierst Du diese beiden Zellen (F2 & G2) mit den Format-Code MMM.
Jetzt kopierst Du die Zelle G2 noch 10 mal nach rechts.

Jetzt wird in F3 folgende Formel eingesetzt, und runter bis zu F4 kopiert..
[code]
=SUMMENPRODUKT($C$3:$C$11;$A$3:$A$11=$E3;MONAT($D$3:$D$11)=MONAT(F$2))
[/code]
In der Spalte E steht Offen und Beauftragt welche als Suchkriterien für die Spalte A dienen.
Das Suchdatum wird jetzt nicht mehr als ein Minimum und Maximum gesucht, sondern als ganzer Monat welcher aus der Zelle F2 ausgelesen wird.
Nun kannst Du F3 unf F4 nach rechts rüber kopieren.
Diese Formel ist doch irgendwie praktischer, oder nicht :wink:. (meine Meinung)

Falls aber deine Liste nicht für ein ganzes Jahr gelten soll, sondern über einen längeren Jahreszeitraum, dann musst Du dich noch mal hier melden da dann meine vorgeschlagene Formel angepasst werden müsste.

Habe mal ein kleines Beispiel angehängt.

Hilft das weiter?


Gruß
balu

Hallo zusammen,
ich benötige die Funktion SUMMEWENNS die ich in OO leider sehr vermisse. Ich habe Folgende Formel die in Excel funktioniert ich leider in OO nicht anwenden kann. Aber evtl. kann mir jemand anders bei meinem Problem helfen:

=SUMMEWENNS($C$1:$C$65000;$A$1:$A$65000;"=Offen";$D$1:$D$65000;">=01.01.2009";$D$1:$D$65000;"<=31.01.2009")

Status Nummer Betrag Datum Jan Feb März usw....
Offen 1 10 01.01.2009 Offen 20
Beauftragt 2 10 05.01.2009 Beauftragt 10
Offen 3 10 06.01.2009
usw. Endlos Tabelle

Ich möchte sie Summen alle Vorgänge mit Status X für die jeweiligen Monate ohne Hilfsspalte(n) angezeigt bekommen. Dafür verwende ich in Excel die oben genannte Formel die leider bei OO nicht funktioniert.
1. Kommt evtl. die SummeWenns Funktion bald?
2. Gibt es eine Alternative?