OpenOffice.info

Hallo Eia,
habe soeben Deine mir unbekannte Variante der Integration von VORLAGE eingebaut. Funktioniert super, VIELEN DANK für den Tipp! Spart ja auch noch Speicher und Rechenzeit. Sieht jetzt so aus:

=WAHL(E5+1;" ";"F1";"F2";"F3";"S1";"S2";"S3";"N1";"N2";"N3";
"RSo";"RS";"RaN";"M";"o")&T(VORLAGE(WAHL(E5+1;"ruhe";"rt";"rt";"rt";"gn";
"gn";"gn";"bl";"bl";"bl";"rso";"rs";"ran";"mi";"gr")))

Bei WAHL bleibe ich aber erstmal.

gripslund

[quote="gripslund"]
Die Sache mit LINKS dient dazu, die von VORLAGE zurückgelieferte, und an den Text angehangene "0" (Null), abzuschneiden. Also statt z.B. "RaN0" steht dann nur noch "RaN".[/quote]
Das brauchst Du nicht.
Wenn Du Zahlen hast, fügst Du eine Vorlage so an:
+VORLAGE("Name")
bei Zeichen machst Du das so:
&T(VORLAGE("Name"))
dann hast Du keine 0, die Du wieder wegnehmen musst.
[quote]
Ich habe nur geschrieben, weil ich 'ne Möglichkeit gesehen habe, das Problem zu lösen, OHNE FLIMMERN. Dass meine Lösung nicht DIE Lösung [/quote]
Ich wollte nichts an Deiner Lösung beanstanden. WAHL ist effektiv eine Möglichkeit. Man sollte immer mit den FUNKTIONEN beginnen, mit denen man sich am sichersten fühlt. Wenn's dann einmal klappt, kann man immer noch nach günstigeren Varianten suchen.
Ich hatte Deinen Beitrag auch falsch verstanden. Du wolltest eine Lösung publizieren und ich hatte verstanden, Du hättest ein Problem damit und wollte anfangen, es einzugrenzen.
Das "Flimmern" kommt nur dann, wenn man die VORLAGE()-Funktion nicht direkt in einer Zelle sondern bei Angabe einer bedingten Formatierung eingibt

Dass das Teil unübersichtlich ist gebe ich unumwunden zu! Ist mir aber auch egal, weil ich es halt einmal ausgeknobelt habe und es - für mich - perfekt funktioniert. Die Begrenzung auf 30 verschiedene Vorlagen kann man zwar anfügen, aber wer braucht denn wirklich MEHR?
Die Sache mit LINKS dient dazu, die von VORLAGE zurückgelieferte, und an den Text angehangene "0" (Null), abzuschneiden. Also statt z.B. "RaN0" steht dann nur noch "RaN". LÄNGE ermittelt dazu die Anzahl Zeichen aus der Tabelle in welcher der eigentliche Plan (alle 14) hinterlegt ist.
O.K.?
Ich habe nur geschrieben, weil ich 'ne Möglichkeit gesehen habe, das Problem zu lösen, OHNE FLIMMERN. Dass meine Lösung nicht DIE Lösung ist - na gut.
Gruß

gripslund

Von welchem Ergebnis soll mit LINKS was genau abgeschnitten werden?
Ich denke mal, die Sache mit der VORLAGE muss ganz zum Schluss mit & angehängt werden, alles andere muss davor passieren.
Und dann würde ich Vorlagen und diese Codes auch in eine [url=http://mypage.bluewin.ch/solkasim/wverweis.ods]WVERVEIS-Tabelle[/url] schreiben und nicht einen so unübersichtlichen (und auch begrenzten) WAHL-Wurm erzeugen.

Hallo,
ja ich weiß, dass das Thema schon etwas älter ist. Ich habe aber auch einen Dienstplan, bei dem mehr als 3 bedingte Formatierungen verwendet werden (etwa acht). Meine Lösung ist aber mit einer daneben liegenden "Hilfszelle" verbunden, welche mir (wiederum per Formel) ermittelt, welchen Zustand die Formatierung sowie der Zellinhalt annehmen sollen. Das Ausgangs-Kriterium liegt in Spalte "E". Davon abhängig sind in meinem Fall 15 Möglichkeiten vorhanden, aber es gehen bis zu 30! Das hängt von "WAHL()" ab. Und bei mir flimmert NICHTS!

=LINKS(WAHL(E5+1;" ";"F1";"F2";"F3";"S1";"S2";"S3";"N1";"N2";
"N3";"RSo";"RS";"RaN";"M";"o")&VORLAGE(WAHL(E5+1;"ruhe";"rt";
"rt";"rt";"gn";"gn";"gn";"bl";"bl";"bl";"rso";"rs";"ran";"mi";"gr"));
LÄNGE(WVERWEIS((WOCHENTAG($C5;2)+(7*$Daten.$K$19-7));
$Plan.$C$1:$Plan.$EL$15;A5+1)))

WVERWEIS und WOCHENTAG ermitteln mir nur aus einem von 14 mgl. Plänen den jeweiligen Dienst für diesen Tag.

Das steht alles in einer Zelle! Das Jahr hat mindestens 365 Tage, es werden also 366 (für 29.2.) Zellen mit dieser Formel belegt.

Hilft das?

gripslund

Hallo zusammen,

meine WENN-Formel sollte auch nur eine Anregung für eine überschaubare Anzahl von Formatierungen sein. Das Zappeln liegt an der Aktualisierungsfunktion von OOo. Hier scheint's, muss noch einiges optimiert werden. Für sehr viele unterschiedliche Formatierungen, würde auch ich zu SVERWEIS oder einem Macro greifen. Aber bei vier oder fünf verschiedenen Formatvorlagen finde ich die WENN-Funktion vollkommen ausreichend und leicht anwendbar.

Viele Grüße
FranzX
-----------------------------------------------------------------
[color=red]TIPP:[/color][url=http://www.cul.de/oocalc.html][color=darkblue]OpenOffice.org Calc - Formeln und Funktionen[/color][/url]

Nach meinen Versuchen geht's mit SVERWEIS bequemer als mit WENN.
Du schreibst alle möglichen Bedingungen untereinander in eine Spalte in einem unbenutzten Tabellenbereich. In die Spalte daneben die Namen der jeweils anzuwendenden Zellvorlage.
Dann kannst Du z.B. als Formel bei der bedingten Formatierung eingeben:
WENN(A1=A1;&T(VORLAGE(SVERWEIS(A1;[Zellbereich mit den Bedingungen und Vorlagen];2;0)))
Evtl. brauchst Du noch ein WENN für den Fall, dass keine Bedingung zutrifft:
WENN(ISTNV(SVERWEIS(A1;[Zellbereich mit den Bedingungen und Vorlagen];2;0);&T(VORLAGE("Standard"));&T(VORLAGE(SVERWEIS(A1;[Zellbereich mit den Bedingungen und Vorlagen];2;0)))

Aber das Flackern bringe ich nicht weg. Und mir scheint, es wird hier auch enorm Rechnerleistung geschluckt. Vielleicht fährst Du besser mit dem Beispiel "Viele Bedingungen" auf der Seite http://www.ooowiki.de/CalcFormatBedingt/FunktionVorlage wo die VORLAGE()-Funktion nicht unter "bedingtes Format" sondern direkt in der Zelle angewendet wird

mfG

Hallo FranzX,

das Funktioniert super. Das war genau die Lösung für meine Dienstplan-Anwendung.
Das Format für die Schriftfarbe habe ich von Standard auf Schwarz umgestellt. Leider zappelt die Tabelle sich ganz schön einen ab.

Hast Du da noch `ne Lösung??

Schönen Gruß und vielen Dank,
Holger

Hallo Stephan,

Nach meinen Erfahrungen kann man das Flackern fast ganz unterdrücken wenn man die Schriftfarbe von Standard auf Schwarz stellt.
Bei mir flackern nur die hellen Schriften. Mit schwarzer Schrift bemerkt man das Flattern nur beim Markieren einer Zelle.

Viele Grüße
FranzX
-----------------------------------------------------------------
[color=red]TIPP:[/color][url=http://www.cul.de/oocalc.html][color=darkblue]OpenOffice.org Calc - Formeln und Funktionen[/color][/url]

Ja, das war mir bekannt, allerdings flackern nach meiner Erfahrung bei dieser Art bedingter Formatierung anschließend die Zellanzeigen.
(nur sofern das Bedingungskriterium wahr ist und die Formatierung auch angewendet wird)



Gruß
Stephan

Hallo zusammen,

man kann eine bedingte Formatierung mit mehr als drei Bedingungen auch ganz ohne Macro und Basic erstellen.
Mann muss die Bedingungen nur Schachteln. Die verschiedenen Formatvorlagen werden dabei mit der Funktion "Vorlage" zugewiesen.

Als Beispiel habe ich eine bedingte Formatierung mit 9 verschiedenen Zellvorlagen erstellt und zugewiesen.

Als Bedingung 1: habe ich eingetragen:

WENN(A1="A";"A"&T(VORLAGE("rot"));WENN(A1="B";"B"&T(VORLAGE("grün"));WENN(A1="C";"C"&T(VORLAGE("blau"));"")))

Als Bedingung 2:

WENN(A1="D";"D"&T(VORLAGE("gelb"));WENN(A1="E";"E"&T(VORLAGE("grau"));WENN(A1="F";"F"&T(VORLAGE("rosa"));"")))

Als Bedingung3:

WENN(A1="G";"G"&T(VORLAGE("Türkis"));WENN(A1="H";"H"&T(VORLAGE("Magenta"));WENN(A1="I";"I"&T(VORLAGE("Braun"));"")))

Als Zellvorlage ist bei allen drei Bedingungen "Standard" eingetragen.

Je nach Eintrag (von A bis I ) wird die Zelle anders eingefärbt.

Vielleicht kann's jemand brauchen!

Viele Grüße
FranzX
-----------------------------------------------------------------
[color=red]TIPP:[/color][url=http://www.cul.de/oocalc.html][color=darkblue]OpenOffice.org Calc - Formeln und Funktionen[/color][/url]