Pfad und Dateiname per Formel?

[hylli]

Ich habe zu meiner Frage folgendes gefunden:
viewtopic.php?t=1277&highlight=pfad+dateiname

Ich möchte in einem Feld per Formel den Pfad+Dateinamen stehen haben, ohne führendes "file:///" und ohne endenden Tabellename also ab "#", also z.B.:
D:\Daten\Dateiname.ods

Das "file:///" habe ich wie folgt wegbekommen:

Code: Alles auswählen

=ERSETZEN(ZELLE("Filename");1;9;""))

Wie bekomme ich den Rest nach dem Dateinamen noch weg?!?

Hat jemand ein einfaches Beispiel für mich?!?

Besten Dank vorab.

Hylli

[Eia]

Zum Beispiel:
=ERSETZEN(ERSETZEN(ZELLE("Filename");FINDEN("'#";ZELLE("Filename"));LÄNGE(ZELLE("Filename"));"");1;9;"")

oder
=TEIL(ZELLE("Filename");FINDEN("///";ZELLE("Filename"))+3;(FINDEN("'#";ZELLE("Filename")))-(FINDEN("///";ZELLE("Filename"))+3))

[Karolus]

Hallo


Noch zwei Beispiele :

=TEIL(ZELLE("Filename");10;FINDEN("'#";ZELLE("Filename"))-10)

=LINKS(ERSETZEN(ZELLE("Filename");1;9;"");FINDEN("'#";ZELLE("Filename"))-10)

Gruß Karo

[hylli]

Danke für Eure Hilfe!!!

Alle Vorschläge funktionieren tadellos!!!

Vielleicht machen sich die Entwickler ja noch daran, das ein wenig zu vereinfachen.

Das ist das Einzige wo Lotus 1-2-3 (noch gezwungenermaßen im Einsatz!) sowohl MS als auch OO voraus ist:

Code: Alles auswählen

@zellzeiger("Dateiname")

Hylli

[Toxitom]

Hey,

also, ich glaube, richtig kannst du das nur mit einer benutzerdefinierten Funktion erreichen.
Das Problem aller Vorschläge ist, dass sie die URL Schreibweise zurückliefern. Also, Leerzeichen werden beispielsweise "maskiert" mit %20, gleiches gilt für Umlaute und Sonderzeichen....
Also, hier eine (sehr) einfache benutzerdefinierte Funktion:

Code: Alles auswählen

function Dateiname
	Dateiname = convertFromURL(thisComponent.url)
end function

Speichern unter Meine Makros -> Standard -> <irgendein Modul> (Wichtig: Muss in der Bibliothek "Standard" gespeichert werden!
Dann in die Zelle schreiben: =DATEINAME() - fertig

Gruss
Thomas

[hylli]

Mag sein, dass dies die sauberste Lösung ist, aber da ich das aufgrund der EDV-Kenntnisse meiner Mitarbeiter an jedem Arbeitsplatz selbst machen müsste, ist mir eine Formel die ich per Mail weitergeben kann doch lieber!

Wie gesagt hoffe ich darauf, dass man seitens der OO-Entwickler eine einfache Funktion zur Verfügung, wie es z.B. bei Lotus 1-2-3 der Fall ist.

Hylli