OpenOffice.info

Verfasst: **Sa, 28.08.2010 08:38**

Hallo zusammen!

Sitze immernoch an meiner Schichttabelle und ich habe folgendes Problem.

Habe zwei saisonale Dienstpläne. D.h. in einem bestimmten Datumsbereich gilt ein bestimmter Dienstplan.
Habe mit einer riesigen WENN-Formel, die ich nicht mehr überblicken kann

, den ersten Schritt geschafft, das ab einem vorbestimmten Datum auf den 2ten SVERWEIS umgeschaltet wird. Das klappt! ABER...es wird ab dem zweiten Datumsabschnitt nicht wieder "zurückgeschalten".
Das "Problem" liegt beim 22ten Nov. (in der Tabelle). Da sollte wieder auf den ersten SVERWEIS umgeschalten werden...tuts aber leider nicht

Seht Euch bitte die Tabelle mal an.
Danke schonmal für Tips und Hilfe.

Gruß WedlWedl

Anbei die Tabelle

Arbeitszeit_2010.ods: (55.05 KiB) 48-mal heruntergeladen

Verfasst: **Sa, 28.08.2010 09:39**

WedlWedl hat geschrieben:Das "Problem" liegt beim 22ten Nov. (in der Tabelle). Da sollte wieder auf den ersten SVERWEIS umgeschalten werden...tuts aber leider nicht

Ich habe deine Formel mal aufgedröselt und mit Kommentaren versehen:

Code: Alles auswählen

=WENN(
	UND(
		A24>=$Schichtdaten.$B$3;        ## gültig von 23.11.2009
		A24<=$Schichtdaten.$B$4         ## gültig bis 02.05.2010
	);
	WENN(                              ## im Zeit-Intervall
		WOCHENTAG(A24;2)>5;
		G24;
		WENN(
			B24="F";
			G24+$Schichtdaten.$F$3;      ## Soll-Zeit 7:36
			G24-$Schichtdaten.$F$3       ## dto.
		)
	);
	WENN(                              ## ausserhalb des Zeitintervalls
		WOCHENTAG(A24;2)>5;
		G24;
		WENN(
			B24="F";
			G24+$Schichtdaten.$M$3;      ## Soll-Zeit 8:00
			G24-$Schichtdaten.$M$3       ## dto.
		)
	)
)

Da wird dann schnell klar, dass du nur unterscheidest, ob der Tag im Intervall [23.11.2009 ; 02.05.2010] liegt oder ausserhalb. Du wirst also wohl ein anderes Zeitintervall angeben müssen.

Noch ein Tip: Wenn du einzelne Zellen oder ggf. auch Zellbereiche benennst (s. NamenFürBereiche), z.B. $Schichtdaten.$B$3 => Sollzeit_1, liest sich so ein Formel-Monster etwas leichter.

Gruß
lorbass

Verfasst: **Sa, 28.08.2010 09:57**

Es scheint also an der Jahreszahl zu hängen?!
Hab es aber auch schon mit [TT.MM] zu machen...ging aber auch nicht so richtig.

Aber danke auf jeden Fall!

Gruß WedlWedl

Verfasst: **Sa, 28.08.2010 10:05**

Hallo
Ich hab gerade nicht viel Zeit, daher nur ein Anfang:
Benenne $Schichtdaten.$A$7:$F$30 mit dem Namen winter ( → Einfügen → Namen → Festlegen ..)
Dito der Bereich hinten mit dem Namen sommer
erstelle in dem Blatt noch einen benannten Bereich plan mit dem Inhalt:

Code: Alles auswählen

23.11.2009	07:36	winter
03.05.2010	08:00	sommer
23.11.2010	07:36	winter

in C3 eines Monatsblattes reicht dann:

Code: Alles auswählen

=SVERWEIS($B3;INDIREKT(SVERWEIS($A3;plan;3;1));2;0)

für Spalte D , E und F die 2 anpassen auf 3 , 4 und 5

Später mehr
Gruß Karo

Verfasst: **Sa, 28.08.2010 10:14**

Wow!
Wie immer Danke! Werd mich gleich dranmachen!

Gruß WedlWedl

OpenOffice.info

SVERWEIS-Schaltung?

SVERWEIS-Schaltung?

Re: SVERWEIS-Schaltung?

Re: SVERWEIS-Schaltung?

Re: SVERWEIS-Schaltung?

Re: SVERWEIS-Schaltung?