Datei aus dem Forum läßt sich nicht downloaden

Setup und Komponenten-übergreifende Probleme.

Moderator: Moderatoren

Benutzeravatar
Faol
****
Beiträge: 170
Registriert: Di, 26.01.2016 21:18

Datei aus dem Forum läßt sich nicht downloaden

Beitrag von Faol » Di, 14.01.2020 18:03

Hallo,
wie kann ich mir die Datei "alle_Pfade.ods" unter nachfolgendem Link downloaden?

Link: http://de.openoffice.info/viewtopic.php?t=53912#p204212


Ich erhalte diese Fehlermeldung:
Information

Die Datei kann nicht übertragen werden.
Gruß
Faol

Tipp des Tages:
Heute schon an eine Sicherungskopie gedacht?


⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒
Win.10 Prof. (x64) • AOO 4.1.6 • LibO 6.3.4.2 (x64)
⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐

Stephan
********
Beiträge: 11372
Registriert: Mi, 30.06.2004 19:36
Wohnort: nahe Berlin

Re: Datei aus dem Forum läßt sich nicht downloaden

Beitrag von Stephan » Di, 14.01.2020 18:54

Das ist ein Fehler in der Forumssoftware der Dateien verschwinden lässt. Ich kann die Datei aber auch auf meinem PC nicht mehr finden.

Hier ist ein fertiges Makro aus https://www.uni-due.de/~abi070/ooo.html, welches das Gleiche erledigt wie die Datei, lediglich werden die Pfade nicht in ein Tabellen- sondern ein Textdokument ausgegeben:

Code: Alles auswählen

Sub DisplayPathSettings
  Dim oPathSettings    ' Der Service PathSettings.
  Dim oPropertySetInfo ' Zugriff auf die Service-Eigenschaften.
  Dim aProperties      ' Enthält alle Service-Eigenschaften.
  Dim oDoc             ' Referenz auf ein neu erstelltes Dokument.
  Dim oText            ' Das Text-Objekt des Dokuments.
  Dim oCursor          ' Cursor im Text-Objekt.
  Dim oProperty        ' Eine Service-Eigenschaft.
  Dim cPropertyName$   ' Der Name der Eigenschaft.
  Dim cPropertyValue   ' Der Wert der Eigenschaft kann ein Array sein oder eine Reihe
                       ' von Strings.
  Dim aPaths           ' Die Pfade als Array.
  Dim cPath$           ' Ein einzelner Pfad aus dem Array.
  Dim j As Integer     ' Indexvariable.
  Dim i As Integer     ' Indexvariable.
  
  oPathSettings = CreateUnoService("com.sun.star.util.PathSettings")
  
  ' Beispiel, wie man die gewünschte einzelne Eigenschaft ermittelt.
  'oPathSettings.Work
  ' Holt die Information über die Eigenschaften der Pfadeinstellungen.
  oPropertySetInfo = oPathSettings.getPropertySetInfo()
      
  ' Bildet ein Array der Eigenschaften.
  aProperties = oPropertySetInfo.getProperties()
   
  ' Erzeugt ein Dokument zur Datenausgabe.
  oDoc = StarDesktop.loadComponentFromURL("private:factory/swriter", _
                                                          "_blank", 0, Array())
  oText = oDoc.getText()
  oCursor = oText.createTextCursor()
   
  oText.insertString(oCursor, "Pfadeinstellungen", False)
  oCursor.ParaStyleName = "Überschrift 1"
  oText.insertControlCharacter(oCursor, _
             com.sun.star.text.ControlCharacter.PARAGRAPH_BREAK, False)
  ' Iteriert durch das Eigenschaften-Array
  '  und schreibt die Informationen über jede Eigenschaft in die Ausgabedatei.
  For i = LBound(aProperties) To UBound(aProperties)
    oProperty = aProperties(i)
    cPropertyName = oProperty.Name
    cPropertyValue = oPathSettings.getPropertyValue(cPropertyName)
      
    oText.insertString(oCursor, cPropertyName, False)
    oCursor.ParaStyleName = "Überschrift 3"
    oText.insertControlCharacter(oCursor, _
                com.sun.star.text.ControlCharacter.PARAGRAPH_BREAK, False)
    If IsArray(cPropertyValue) Then
      ' Manchmal werden mehrere URLs als Array zurückgegeben.
      aPaths = cPropertyValue
    ElseIf Len(cPropertyValue) > 0 Then
      ' Manchmal werden mehrere URLs durch Semikolon getrennt.
      ' Sie werden in ein String-Array gesplittet.
      aPaths = Split(cPropertyValue, ";")
    Else
      aPaths = Array()
    End If
    For j = LBound(aPaths) To UBound(aPaths)
      cPath = aPaths(j)
      oText.insertString(oCursor, cPath, False)
      oText.insertControlCharacter(oCursor, _
         com.sun.star.text.ControlCharacter.PARAGRAPH_BREAK, False)
    Next
      
    oText.insertControlCharacter(oCursor, _
        com.sun.star.text.ControlCharacter.PARAGRAPH_BREAK, False)
   Next i
End Sub

Gruß
Stephan

Benutzeravatar
Faol
****
Beiträge: 170
Registriert: Di, 26.01.2016 21:18

Re: Datei aus dem Forum läßt sich nicht downloaden

Beitrag von Faol » Di, 14.01.2020 19:07

Hallo Stephan,

vielen Dank für die Informationen.

Etwas peinlich, das Makro kenne ich sogar, wußte aber nicht mehr wo ich es gelesen hatte.
Stephan hat geschrieben:lediglich werden die Pfade nicht in ein Tabellen- sondern ein Textdokument ausgegeben:
Das ist kein Problem für mich.

Wollte nur für ein aktuelles Projekt von mir wissen, wie man per Makro an die Pfade kommt.
Gruß
Faol

Tipp des Tages:
Heute schon an eine Sicherungskopie gedacht?


⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒
Win.10 Prof. (x64) • AOO 4.1.6 • LibO 6.3.4.2 (x64)
⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐

Benutzeravatar
balu
********
Beiträge: 3758
Registriert: Fr, 24.08.2007 00:28
Wohnort: Warstein

Re: Datei aus dem Forum läßt sich nicht downloaden

Beitrag von balu » Do, 16.01.2020 15:57

Hallo

ich habe die besagte Datei noch auf meiner Fättplatte gefunden. Ich häng sie hier gleich mal an.


Gruß
balu
Dateianhänge
alle_Pfade.ods
(14.75 KiB) 6-mal heruntergeladen
Sei öfter mal ein Faultier, sag öfter mal "Ach was!" Dann kriegst du keinen Herzinfarkt, und hast ne menge Spass.

wehr rächtschraipfähler findet khan si behalden :D

Benutzeravatar
Faol
****
Beiträge: 170
Registriert: Di, 26.01.2016 21:18

Re: Datei aus dem Forum läßt sich nicht downloaden

Beitrag von Faol » Do, 16.01.2020 16:00

Hallo Balu,

vielen Dank!
Gruß
Faol

Tipp des Tages:
Heute schon an eine Sicherungskopie gedacht?


⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒⇒
Win.10 Prof. (x64) • AOO 4.1.6 • LibO 6.3.4.2 (x64)
⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐⇐

Benutzeravatar
balu
********
Beiträge: 3758
Registriert: Fr, 24.08.2007 00:28
Wohnort: Warstein

Re: Datei aus dem Forum läßt sich nicht downloaden

Beitrag von balu » Do, 16.01.2020 23:24

Hallo Faol.

Gern geschehen 8)


Gruß
balu
Sei öfter mal ein Faultier, sag öfter mal "Ach was!" Dann kriegst du keinen Herzinfarkt, und hast ne menge Spass.

wehr rächtschraipfähler findet khan si behalden :D

Antworten