OpenOffice.info

Hallo Sigurd,

[quote="Sigurd"]das ist kein Problem; hier ist der Kalender.
Grüße
Sigurd[/quote]
Danke, Problem behoben (eine Kopie ist bei mir). Ich hab mal ein wenig "herumgeblättert" darin, für ein intensiveres Studium fehlt etwas die Zeit. Ob ich Einzelheiten oder alles daraus verwende, weiß ich nicht; auf jeden Fall versuche ich, gewisse Formeln nachzuvollziehen.

Aus einer "Geburtstagsdatei" habe ich mal ein paar Zeilen/ Spalten herauskopiert. Basis des ganzen ist Excel, deswegen sind da manchmal ein paar verschrobene Formeln sichtbar. Allerdings hat OO Calc das ganze eingelsen und dort funktionierten alle Formeln gleichgut wie im Excel.

Gruß

Constructus

p.s.: die Angaben der "altdeutschen Monatsnamen" lassen sich auch in Kalendern verwenden. Die Zurdnungen der Sternzeichen zu Datumsangaben sind natürlich auch woanders zu finden. Und die Berechnungen zum Alter der Welt sind nicht ganz ernst gemeint...

Hallo Gert,

vielen Dank für den Hinweis. Die Formeln habe ich ausprobiert; es klappt. Für meine Anwendung könnte man sie so umbauen:
=WENN(MONAT(A35+1)<>MONAT($A$34);"";A35+1)
Dann ist der Februar mit ungleicher Länge abgedeckt.
Allerdings möchte ich in diesem Kalender alle Tage haben. :? Dies hat reine optische Gründe; ich möchte keine leeren Zeilen und / oder keine unterschiedlich langen Tabellen.
Dennoch – es wird für mögliche spätere Anwendungen aufgehoben. :D

Grüße
Sigurd

Hallo Sigurd,
Formeln für die Leerzellen im [b]Febraur[/b] :
A63 [b]=WENN(Monat(A62+1)<>MONAT(A62);"";A62+1)[/b] ist auch für alle Monate mit 30Tagen gültig, ZellAdressen entsprechend anpassen.

A64 [b]=WENN(A63="";"")[/b] ebenso in A65

In Spalte E wird für die o.g. Zellen jetzt der [b]Nikolaustag (der ja kein Feiertag ist)[/b] angezeigt. Dies unterbinden wir mit der Formel in :
E63 bis E65 (Febraur) [b]WENN(A63="";"";[/b] wird vor die "Feiertagsformel" angefügt. Dies gilt auch für die 30Tage_Monate des Jahres.

mfg
Gert

Hallo Constructus,

das ist kein Problem; hier ist der Kalender.

Grüße
Sigurd

Hallo Sigurd,

wenn das Ergebnis nicht ganz geheim ist... 8) möchte ich doch gern einmal studieren, was ihr da so zusammengestrickt habt. Ob Du's noch mal einstellen kannst, wenn's voraussichtlich nicht erhebliches mehr zu ändern gibt?

Gruß

Constructus

hallo Balu,

vielen Dank für Kommentar.
Die Formel ist jetzt klar; die bedingte Formatierung in Spalte C sind gelöscht. :D
So, jetzt glaube ich, dass der Kalender soweit fertig ist. Wenn er noch einmal eingestellt werden sollte, sage bitte Bescheid. Ich werde sowieso noch einige Male hier hereinschauen.

Grüße
Sigurd

P.S. Sollten noch Fragen auftauchen, so würde ich mich einfach melden

=WAHL(WENN(UND(WOCHENTAG(A35)=7;SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1));1;WENN(UND(WOCHENTAG(A35)=1;SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1));2;WENN(SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1);3;WENN(WOCHENTAG(A35)=7;4;WENN(WOCHENTAG(A35)=1;5;6)))));1;2;3;4;5;"")

=WAHL(WENN(A1+1=2;1;WENN(A1+2=4;2;3));"1+1=2";"2+2=4";"hab kein bock zum rechnen!")

=SUMMENPRODUKT(A1:A5=1;B1:B5="Ä")

=WENN(ZÄHLENWENN(Feiertagsliste.$A$8:$A$143;A35)=1;SVERWEIS(A35;Feiertagsliste.$A$8:$D$143;4;0);"")

SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$D$8:$D$143=1)

Hallo Sigurd,

sorry, aber meine Zeiteinteilung ist momentan etwas chaotisch. Hatte diesen Beitrag schon fast fertig, blos noch nicht gepostet.


Die Modifizierungen im einzelnen.

zu 2.)
Du hattest in der Hilfsspalte UND in der "Bedingten Formatierung" Berechnungen angestellt. Und das habe ich jetzt komplett verworfen. Jetzt wird alles auf einmal in einer Zelle ausgeführt. Dazu habe ich die Formel WAHL eingesetzt. Das genügte mir aber noch nicht, da mir die Abfrage der Feiertage nicht so richtig gefiel. Und deshalb habe ich da die Formel SUMMENPRODUKT eingesetzt. Und als fertige Formel sieht das nun so aus.

[code]
=WAHL(WENN(UND(WOCHENTAG(A35)=7;SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1));1;WENN(UND(WOCHENTAG(A35)=1;SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1));2;WENN(SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$G$8:$G$143=1);3;WENN(WOCHENTAG(A35)=7;4;WENN(WOCHENTAG(A35)=1;5;6)))));1;2;3;4;5;"")
[/code]

Was passiert da jetzt!?
WAHL gibt Intern eine Indexzahl nach einer Überprüfung aus, die dann anschließend abgearbeitet wird. Ein einfaches Beispiel (ohne Fehler abfangen):
=WAHL(A2;"1.INDEX";"2.INDEX";"3.INDEX")
Auch wenn es nicht sofort zu erkennen ist, ist nur die Zelle A2 dafür verantwortlich wie es weitergehen soll. Denn wenn man jetzt dort eine
1 eingibt, dann wird "1.INDEX" ausgegeben.
Und bei 2 -> "2.INDEX",
und bei 3 -> "3.INDEX".

Beim aufbau einer WAHL-Formel ist zu beachten, das die Reihenfolge der Überprüfung mit dem Ergebnis übereinstimmt. Nicht das dann ein falscher Wert rauskommt. Wenn man z.B. überprüft ob in A2 eine 2 ist, dann sollte man schon darauf achten das man bei "2.INDEX" anlangt, und nicht bei "3.INDEX". Man muss also nur seine eigene vorher festgelegte Reihenfolge nicht aus den Augen verlieren.


Mit einer WENN-DANN-SONST Abfrage sieht das dann so aus.
[code]
=WAHL(WENN(A1+1=2;1;WENN(A1+2=4;2;3));"1+1=2";"2+2=4";"hab kein bock zum rechnen!")
[/code]

Die Funktionserklärung:
Jetzt ist deutlich zu sehen, wo die Intene Indexzahl verarbeitet wird. Und zwar ist das der Bereich nach der ersten öffnenden Klammer "(", bis zu den beiden schließenden Klammern "))". Und warum ist das so!? Weil jede Formelfunktion, egal ob WENN, ODER WOCHENTAG eine öffnende und eine schließende Klammer hat. Und wenn innerhalb einer Formelfunktion verschachtelungen stattfinden, müssen ja am ende dementsprechend mehrere schließende Klammern gesetzt werden. In diesem Fall sind das dann zwei (2).

Wenn A1+1=2, dann ist die Indexzahl gleich 1. Und es wird bei dem Index 1, also bei der Textausgabe von "1+1=2" weitergemacht. Und da ja dort nur der Text ausgegeben wird, ist dann die Formel zu ende.

Wenn jetzt aber A1+1 nicht 2 ist, wird jetzt die nächste WENN abgearbeitet.

Wenn A1+2=4, dann ist die Indexzahl gleich 2. Und es wird bei dem Index 2, also bei der Textausgabe von "2+2=4" weitergemacht. Und da ja dort nur der Text ausgegeben wird, ist dann die Formel zu ende.

Und wenn jetzt auch diese WENN-Abfrage nicht stimmt, dann wird die Indexzahl 3 abgearbeitet. Es wird dann der Text "hab kein bock zum rechnen!" ausgegeben.




Und nun zu SUMMENPRODUKT.
Um es ganz lapidar zu sagen, heisst das. Wenn alle Bedingungen erfüllt sind, dann ist der Wahrheitswert der Formel gleich WAHR (1). Ein einfaches Beispiel.
[code]
=SUMMENPRODUKT(A1:A5=1;B1:B5="Ä")
[/code]
Im Zellbereich von A1 bis A5 stehen folgende Zahlen: 1_2_3_4_1
Im Zellbereich von B1 bis B5 stehen folgende Buchstaben: A_Ä_B_D_Ä

Das heisst.
A1:A5=1
SUMMENPRODUKT geht nun daher und schaut nach, wo überall in diesem Bereich eine 1 steht.

B1:B5="Ä"
SUMMENPRODUKT geht nun daher und schaut nach, wo überall in diesem Bereich das Ä steht.

Wenn in beiden Fällen jeweils das Suchkriterium 1x vorhanden ist, dann wird eine 1 als Ergebnis ausgegeben. Wenn aber in A2 anstatt eine 2 eine 1 drin steht, dann wird eine 2 zurückgegeben.
Uns jedoch aber interessiert nur der Rückgabewert 1. Denn anstatt wie vorher:
[code]
=WENN(ZÄHLENWENN(Feiertagsliste.$A$8:$A$143;A35)=1;SVERWEIS(A35;Feiertagsliste.$A$8:$D$143;4;0);"")
[/code]
zu schreiben, sieht das jetzt so aus.
[code]
SUMMENPRODUKT($Feiertagsliste.$A$8:$A$143=A35;$Feiertagsliste.$D$8:$D$143=1)
[/code]

Na ja, nicht genau das gleiche, aber da ja jetzt keine WENN-Abfrage stattfindet, ist es halt ähnlich.
Denn bei der alten Formel musste erst die ZÄHLENWENN-Bedingung erfüllt sein, um einen Wert über SVERWEIS zu bekommen. Und dabei wird jedesmal auf das Datum in A35 zugegriffen, und erst danach der Wert aus der 4.Spalte in der Feiertagsliste zurückgegeben.
Mit SUMMENPRODUKT geschieht das fast parallel zeitgleich, da sie eine Matrixformel ist (ganz grob gesagt). Näheres dazu im Wiki: http://www.ooowiki.de/CalcFunktionenMatrix/Matrix



[quote="Sigurd"]
Bei der Matrixfunktion SUMMENPRODUKT (Feiertage=A35;FeiertagsAuswahl=1) hätte ich eigentlich keinen Wert von 0 und 1 erwartet…
[/quote]

Wenn beide zu überprüfende Werte jeweils einmal vorhanden sind, wird eine 1 ausgegeben. Ist z.B. nur der Feiertag vorhanden, aber keine FeiertagsAuswahl, dann ist das Ergebnis gleich Null (0). Sorry, aber ich krieg das mit dem Erklären momentan nicht so richtig hin.



Änderungsvorschlag:
In der ausgeblendeten Spalte C hast Du "Bedingte Formatierungen" drin.
Ist überflüssig. Bitte löschen. Es erhöht nur den Rechenaufwand. Und je größer ein Projekt, umso schneller macht sich das bemerkbar. Ich spreche aus Erfahrung.

Noch ein Tipp:
Im Dezemberblatt hast Du in A34 folgende Formel stehen.
=DATUM(Deckblatt.$D$52;MONAT(November.A34)+1;1)
Das deutet darauf hin, dass Du die gute Idee hattest ein erstelltes Tabellenblat einfach zu kopieren. Nur ist das so, das Calc automatisch in das richtige Jahr mit den richtigen Monat umrechnet. Wenn Dezember(12) + 1 theoretisch 13 ergeben würde (im gregorianischen Kalender gibt es keinen 13.Monat), macht Calc sofort Januar im darauffolgenden Jahr daraus.
Beispiel:
01.12.2009 + 1 Monat, ergibt automatisch 01.01.2010
Also musst Du für dein Tabellenblatt "Januar plus" dort in A34 keine andere Formel einsetzen.
Das aber nur so am Rande.



[quote="Sigurd"]
Alles in Allem ist der Kalender für mich bis jetzt sehr gut geworden, er übertrifft sogar meine damaligen Erwartungen – und das im Fernlehrgang. Ein „Danke schön“ für Deine Hilfestellungen; sie sind sehr gut angekommen!
[/quote]

Danke! Danke! Danke! :mrgreen:
Schön zu hören. Ist wirklich ein gutes und schönes gefühl. :lol:



Gruß
balu

Hallo Balu,

vielen Dank für Deine Änderungsvorschläge. Sie sind in den Kalender eingeflossen und konnten, bis auf ein paar Dinge, nachvollzogen werden:
Bei der Funktion WAHL gehe ich davon aus, dass der Klammerausdruck den Index darstellt und 1;2;…6 die Werte darstellt. Ist eine Reihenfolge bei den Bedingungen beim Index einzuhalten?
Bei der Matrixfunktion SUMMENPRODUKT (Feiertage=A35;FeiertagsAuswahl=1) hätte ich eigentlich keinen Wert von 0 und 1 erwartet…

Der Reiter Feiertage ist geändert; Spalte A und F sind getauscht. Ein doppelter Feiertag kann mit 0 ausgeblendet werden.

Alles in Allem ist der Kalender für mich bis jetzt sehr gut geworden, er übertrifft sogar meine damaligen Erwartungen – und das im Fernlehrgang. Ein „Danke schön“ für Deine Hilfestellungen; sie sind sehr gut angekommen!

Grüße
Sigurd

Hallo Sigurd,

das sieht ja schon recht gut aus. :lol:

Aber! Die Handhabung mit den Feiertagen gefällt mir noch nicht. :?

Ich hab in deinem Kalender, im Tabellenblatt [b]"Dezember"[/b] (und nur dort), mal ein paar Modifizierungen vorgenommen.

1.)
So wie ich es schon beschrieben hatte, ist jetzt die versteckte Hilfsspalte N gelöscht.

2.)
In der neu eingefügten Hilsspalte C habe ich jetzt neue Formeln eingesetzt.

3.)
Die Formeln, da wo der Feiertagsname angezeigt wird, habe ich auch modifiziert.

4.)
Habe eine neue Tabelle mit dem Namen "Feiertagsliste" eingefügt. Die hatte ich mir selber erstellt, und jetzt ein wenig angepasst.


Und mit meinen Modifizierungen geht das ganze jetzt mit den Feiertagen auch viel einfacher. Genaueres steht im Tabellenblatt "Feiertagsliste"

Ich bin mit meinen Erklärungen der Modifizierungen noch nicht ganzu fertig. Sobals ich das bin, schreibe ich sie hier rein.



Gruß
balu


[edit 09.08.2008 - 13:32]
Auf Grund eines gedankenfehler habe ich die Datei gegen eine andere ausgetauscht.

=WENN(ZÄHLENWENN(Feiertage.$A$2:$A$58;A40)=1;SVERWEIS(A40;Feiertage.$A$2:$B$58;2;0);"")

=WENN(WOCHENTAG($A40)=2;"KW";"")

=WENN(J40<>"";"Kw";"")

=WENN(WOCHENTAG(A40)=2;KALENDERWOCHE((A40);2);"")

=WENN(WOCHENTAG(A40)=2;KALENDERWOCHE(A40;2);"")

Hallo Sigrurd,

RESPEKT![img]http://smilie-land.de/t/q-s/schilder/schild0081.gif[/img]
Mir gefällt deine Idee und das Layout sehr gut. :D
Ist mal was anderes, und nicht nur der reine
[i]"Ach Guck mal wie schön!... Und wo Kann ich jetzt da noch Notizen von Hand rein schreiben!?"-Kalender[/i]. Er ist nicht nur schön, sondern auch noch sinnvoll praktisch. Meine ehrliche Meinung. :lol:

Jetzt aber wieder zurück an die Arbeit.

Zellvorlagen Mond_Samstag und Mond_Sonntag:
Bei Ausrichtung hast Du Horizontal und Vertikal auf Standard, und nicht wie bei Mond auf Zentriert und Mitte stehen.

6. Dezember, und nicht nur dort!!
Du hast folgende Formel eingesetzt:
[code]
=WENN(ZÄHLENWENN(Feiertage.$A$2:$A$58;A40)=1;SVERWEIS(A40;Feiertage.$A$2:$B$58;2;0);"")
[/code]
Es ist ja logisch, das dann bei Doppelten Datum nichts angezeigt wird. Denn wenn ZÄHLENWENN mehr als 1x das Datum findet, in diesem fall 2x, dann ist ja die Bedingung für Wahr NICHT erfüllt, und es wird "" (nichts) gemacht. In der Formel steht ja Eindeutig, dass ZÄHLENWENN überprüfen soll ob das Suchkriterium GENAU 1x (=1) vorhanden ist. Da ja aber das Datum mindestens 2x vorhanden ist, passt ja die Abfrage nicht.
So steht's in der Formel, und so wird's auch gemacht.

Abhilfe:
Einfach das =1 löschen.
Denn wenn jetzt ZÄHLENWENN das Suchkriterium ein, oder mehrmals findet, ist die Bedingung erfüllt, und es geht mit SVERWEIS weiter.
An dieser Stelle noch der Hinweis, das SVERWEIS bei dem ersten auftreten des Suchkriteriums dort weiter macht. Es wird also der allererste Eintrag von oben zurückgegeben.


DRUCKEN:
Nix Druckbereiche defenieren!!!

Meine Empfehlung.
Spalten löschen!!!

Du hast eine versteckte Spalte N, und wenn Du jetzt dein Kalenderblatt ein wenig umbaust, brauchst Du keinen extra Druckbereich zu defenieren. Okay, das bedeutet wieder etwas mehrarbeit für den Anfang, hat aber auch seine Vorteile.

Auf Spalte C rechtsklicken, und "Spalten einfügen".
Nun kopierst Du deine Formeln aus der versteckten Spalte, müsste jetzt die Spale O sein, in die NEUE Spalte C. Nun musst Du allerdings deine Bedingten Formatierungen neu adressieren. Aber das machst Du ja jetzt auch nur einmalig, da Du ja dann nach getaner Arbeit die Tabellenblätter kopierst.
Jetzt löscht Du zur sicherheit die Spalten N, O, und P.


Du musst auch noch das Bild ein bisschen mehr nach links setzen, um damit es richtig auf der Seite positioniert wird. Denn wenn Du es nicht verschiebst, wird es abgeschnitten, und auf eine nächste Seite ausgegeben. Und wenn es auch nur vielleicht 5 Pixel breit auf der nächsten Seite ausgedruckt wird, so ist das doch ein unschöner effekt.



Tipps:
In der Spalte K hasat Du folgende Formel:
[code]
=WENN(WOCHENTAG($A40)=2;"KW";"")
[/code]
Machs dir einfacher, und ersetze sie durch folgende:
[code]
=WENN(J40<>"";"Kw";"")
[/code]
Du fragst doch schon in der Spalte J die Kalenderwoche ab, warum dann noch mal das ganze Spielchen in K wiederholen? So eine einfache Vergleichsüberprüfung auf eine nicht leere Zelle geht doch für Calc viel schneller, als wenn es erst noch den internen Kalender zur überprüfung der Kalenderwoche bemühen muss. Da muss Calc doch nur zusätzlich rechnen, und das dauert länger.


[code]
=WENN(WOCHENTAG(A40)=2;KALENDERWOCHE((A40);2);"")
[/code]
Bitte in das hier ändern
[code]
=WENN(WOCHENTAG(A40)=2;KALENDERWOCHE(A40;2);"")
[/code]

Was bedeuten denn die Zellen C34 + D34!?
Darauf kann ich mir nichts reimen.

Und wie schon gesagt; ändere deine Datumsspalte, wo der Wochentag ausgegeben wird, ab. Und mach es so wie ich schon weiter vorne beschrieben hatte.


Warum läßt Du dir den Kalendermonat über das Seitenlayout in der Kopfzeile ausgeben? Wäre es nicht schöner, wenn Du das im jeweiligen Kalenderblatt selber machst!? Da hast du doch dann viel mehr gestallterische möglichkeiten. Aber das ist ja schlußendlich deine Entscheidung.


Das mit dem verschwinden der Mondsymbole kann ich momentan nicht verstehen. Beschreib das doch noch mal etwas genauer, im welchen Jahr ist dir das aufgefallen?


Ach ja! Hätte ich jetzt beinahe vergessen!
Wie Du das hinbekommst, das am Monatsende nicht der Tag vom nächsten Monat angezeigt wird (insbesondere im Februar), weisst Du, oder brauchst Du dafür hilfe!?


Das er mottco braucht ist mir wohl auch wieder ein- und aufgefallen, aber für das was ich eben beschrieben habe, ist das uninteressant gewesen.


Gruß
balu

Hallo Sigurd,

[quote="Sigurd"]
PS: deinen Tipp mit den Wochentagen kann ich nicht nehmen, da hängt noch ein Komma dran.
[/quote]
Ja upppss :shock: Fehler meinerseits! Hatte mich da leider vertippt. :oops:
Anstatt [i]NNNN [/i]
nimm [b][color=#0000FF]NNN[/color][/b]
leider 1x N zuviel.

Mit den "Roten Faden" bezog ich mich auf mich selbst.

Wenn Du dich hier im Forum anmeldest, dann ist die Sache mit dem Anhang kein Problem. Falls Du dich aber, aus irgendwelchen gründen, nicht anmelden willst (kannst), dann schau mal [url=http://de.openoffice.info/viewtopic.php?f=2&t=18504&sid=1f4e6212fbaf06159cb52078895aed3f&sid=1f4e6212fbaf06159cb52078895aed3f#p77785]hier[/url] nach. Mich persönlich würde es schon interessieren, was Du da schönes programmiert hast. Und wer weiss, vielleicht läßt er sich ja auch noch in einem etwas größeren Stiel veröffentlichen. :D


Gruß
balu

Hallo Constructus,

[quote="Constructus"]
da ich irgendwann auch mal etwas in diesem Thread verfaßt hatte, verfolgt mich euer Thema unter ‘eigene Nachrichten‘ permanent... Nein, nein, nicht böse sein, der Onkel macht nur Spaß! :lol:

[/quote]
Tja, mein lieber Constructus! Wie heißt es da so schön!?
Mitgegangen, mitgefangen! :mrgreen:
Gell!? Wir verstehn uns schon. :wink:

Spaß beiseite.
Jetzt wird's ernst. Und Ernst wird jetzt eingeschult :lol:

Ich muss zu meiner eigenen Schande :cry: gestehen, das irgendwann mir das ganze ein wenig aus den Rudern geglitten ist. Es ist halt auch alles nicht so einfach, wenn man lieber Gedichte vorträgt, anstatt selber welche zu verfassen. Aber ich werde mich jetzt wieder etwas intensiver darum kümmern.
Auch wenn es sich noch so Paradox anhört, ich muss mir jetzt erstmal selber wieder die Zeit nehmen, meine bisherigen Beiträge zu studieren. Denn den berühmten Roten faden wieder aufzunehmen, fällt mir momentan etwas schwer. Jedoch ich werd's machen.


[quote="Constructus"]
Für 1 Seite DIN A 4 ist der Aufwand doch recht hoch?

[/quote]
Wenn der Kalender fertig ist, dann zeigt er automatisch alle einstellbare Feiertage an. Und dann ist noch Platz für entweder die Mondphasen, oder die Kalenderwochen.
Aber ab wann wäre denn der Aufwand, deiner Meinung nach, nicht "zu hoch"!?
Das kann ich dir sagen.
Jetzt ist er noch nicht zu hoch!
Wenn Du mit "3- Monats- Kalender" das meinst, was ich mir denke (3 Monatsübersicht pro Blatt), dann sieht die Sache schon etwas anders aus. Aber auch sowas hatte ich ja schon programmiert, und auf der Proo-Box veröffentlicht. Allerdings ist der Aufwand bei so einem Kalender davon abhängig, ob er
1.) Pro Tabellenblatt 3 Monate anzeigen soll, das wären dann mindestens 12 Tabellenblätter (so wie mein veröffentlichter).
oder
2.) Nur ein Blatt mit den 3 Monaten, und dann für jeden Ausdruck den Startmonat wechseln.
Beide Methoden haben ihre Vor- und Nachteile! Doch das ist prinzipiell ein anderes Thema, und gehört nicht hier rein.


Mal schaun, was ich jetzt am WE hinbekomme, damit man hier in diesem Thread einen besseren überlick bekommt.


Bin in einer Hinsicht wohl vielleicht ein etwas fortgeschrittener Laie, aber auf ein Wiki, oder dergleichen, habe ich keinen Bock.
Mir gefällt das hier so wie es ist. Denn dadurch steht man mit anderen Usern im engeren Kontakt, und man kann ganz anders auf Wünsche und Probleme eingehen.



Gruß
balu

Hallo ihr eifrigen Luxus- Kalenderfabrikanten, :D

da ich irgendwann auch mal etwas in diesem Thread verfaßt hatte, verfolgt mich euer Thema unter ‘eigene Nachrichten‘ permanent... Nein, nein, nicht böse sein, der Onkel macht nur Spaß! :lol:
Leider muß ich zugeben, daß ich zu wenig Energie besitze, den Kalender Schritt für Schritt anhand dieser Beiträge nachzubasteln. :(
Interessant wäre für mich zunächst einmal, für was dieses Programm (?)/ die Datei denn alles einsetzbar ist. Für 1 Seite DIN A 4 ist der Aufwand doch recht hoch? Ich glaube zwar, daß das irgendwo in 27 Seiten Beitragstext versteckt steht, aber eine zusammenfassende Art Beschreibung oder Einleitung wäre auch für mich vielleicht ganz gut? :?
Wann endlich gibt es denn die finale Version?? {Dies im Sinne von OO 3.0, bitte nicht bierernst nehmen...} Ich hab noch nicht irgendwo anders gesucht, aber könnte das Ding auch als HowTo oder WIKI aufgebaut werden? 8) Nicht schimpfen, ich mein's nicht böse...

Anm.:
Ich habe vor ca. 10 Jahren (!!) einmal ein Fremd- Kalenderprogramm eingesetzt, welches wohl noch auf DOS- Basis arbeitete, und wo man auch einfache Bilder einfügen konnte. Das ganze paßte auf eine 1,44 MB- Diskette (!). Dieses Programm hatte ich im Word aufgerufen und die Kalendertage nach Excel kopiert, weil ich das ganze als 3- Monats- Kalender aufbauen wollte, was beim Original in Word nicht ging. [Dies war noch zu Zeiten, wo OO im WIN nicht existent war... :( ] Vielleicht kann der Calc- Kalender noch soweit erweitert werden, daß er auch die 3- Monats- Funktion direkt hat?

Weiter viel Spaß von Constructus

P. s.: hallo Sigurd, bei Dir fehlen einige Angaben, die bei anderen sichtbar sind. Traust Du Dich nicht, Dich hier anzumelden? Wäre vielleict nicht schlecht... :)

=SVERWEIS(A1;B3:C6;2;0)&T(VORLAGE(SVERWEIS(AKTUELL();C3:D6;2;0)))

Hallo,

für den Fall, dass die Funktionsweise der "Sprechenden Ampel" verständlich ist, kommt hier jetzt noch eine alternative.

Bevor wir jetzt aber die Formel ändern, müssen die Spalten C und D getauscht werden. Also C wandert nach D, und D nach C.

Und nun zur Formel.
Die bestehenden Suchbereiche in den SVERWEISen müssen nach dem Spaltentausch noch angepasst werden, und gleichzeitig wird die zweite SVERWEIS noch um eine Funktion ergänzt. Die da lautet:

[b][color=#0000FF]AKTUELL()[/color][/b]
[u][i]Ermittelt den aktuellen Wert der Formel an der Position, an der diese Funktion steht.[/i][/u]

Das heißt, das der Wert der in der Zelle A8 steht, ausgewertet wird. Da wir ja wissen, das die erste SVERWEIS einen Text, z.B. "Freie Fahrt" rausgibt, können wir doch diesen Text nehmen und ihn weiterverarbeiten. Also warum ein weiteres mal in der zweiten SVERWEIS nach dem gleichen Suchparameter suchen, wenn wir doch schon einen Wert haben? Und genau dort wird jetzt AKTUELL() eingesetzt. Die nun komplett zu ändernde Formel in A8 lautet jetzt:

[code]=SVERWEIS(A1;B3:C6;2;0)&T(VORLAGE(SVERWEIS(AKTUELL();C3:D6;2;0)))[/code]


Na dann, viel Spaß beim experimentieren. :D

Gruß
balu

=SVERWEIS(A1;B3:D6;3;0)

=T(VORLAGE(SVERWEIS(A1;B3:C6;2;0)))

=SVERWEIS(A1;B3:D6;3;0)&T(VORLAGE(SVERWEIS(A1;B3:C6;2;0)))

Hallo Sigurd,

ja jetzt versteh ich :wink: . Wie das nun mal halt so im leben ist, lauert der Dreckfehler überall :D .

Das mit VORLAGE muss nicht unbedingt ein Lindwurm sein, mann kann das sich auch "zusammen zaubern".

Mal angenommen Du willst eine "Ampel" programmieren, die nicht nur die Farben darstellt, sondern das auch noch schriftlich anzeigt. Als Beispiel soll bei GRÜN die Zelle Grün dargestellt werden, und gleichzeitig erscheint auch noch in dieser Zelle der Text "Frei Fahrt". Das zu Programmieren ist gar nicht so kompliziert, es bedarf nur einer gewissen vorarbeit.
Als da wären:
Mindestens drei Vorlagen erstellen, die Sinnigerweise die Namen ROT, GELB, und GRÜN heißen.
Jetzt wird im Tabellenblatt z.B untereinander die Namen der Vorlagen eingetragen. Am besten in der gleichen Schreibweise wie die Vorlagen auch gespeichert sind.
Rechts daneben wird der Text reingeschrieben, der hinterher erscheinen soll. z.B bei GRÜN = Frei Fahrt usw...
Links neben den Vorlagen werden sie nummewriert. Also 1 = ROT 2 = GRÜN......

Nun wird eine "Simple" Formel erstellt, und zwar wie folgt:
Um unser recht einfaches Beispiel zu verstehen, verzichten wir jetzt mal auf eine Fehlerüberpüfung, deshalb ist sie schnell erstellt, und auch schnell verstanden.
Die zu suchende Zahl wird in A1 eingegeben.
Un die folgende Formel geben wir jetzt in A8 ein.
Als erstes nehmen wir eine ganz einfache SVERWEIS. Das Suchkriterium steht ja in A1, und die Suchmatrix ist jetzt als Beispiel der Bereich B3:D6. Die Suchmatrix ist jetzt also eine 3x4 Matrix, also 3 Spalten, und 4 Zeilen. Wir wollen nun aber den Text, also den dritten Spaltenindex, angezeigt bekommen. Und dann sagen wir noch, dass die Suchmatrix NICHT (0) Sortiert vorliegt. Und dadurch schaut jetzt unsere Formel wie folgt aus.
[code]=SVERWEIS(A1;B3:D6;3;0)
[/code]

Wenn jetzt z.B. in A1 die Zahl 3 eingegeben wird, steht jetzt in A8 der Text "Frei Fahrt"

Das war doch gar nicht so schwer. Oder!? :D

Nun kümmern wir uns um die VORLAGE.

Normalerweise reicht es, wenn wir einfach sagen =VORLAGE("GRÜN"), und schon wird die Zelle Grün markiert. Für unsere Zwecke ist das aber nicht sinnvoll, da wir ja dann andauernd von Hand den Namen in VORLAGE ändern müssten, also machen wir das ganz einfach.
Wie eben zu sehen, gibt ja SVERWEIS einen "Text" aus, und genau diesen Umstand machen wir uns jetzt zu nutze. Wir packen nämlich jetzt eine SVERWEIS in die VORLAGE rein, und verbinden die erste SVERWEIS mit VORLAGE durch ein "&", und schon sind wir fast fertig. Doch das hat noch einen kleinen schönheitsfehler, denn dadurch wird am Ende des zurückzugebenden Textes eine Null (0) angehängt. Dies können wir aber ganz Easy umgehen, indem wir noch die Funktion "T" voranstellen.

Und nun zur Formel für VORLAGE:
Die einzusetzende SVERWEIS ist mit der erst beschriebenen fast identisch, nur das jetzt nicht der 3. Spaltenindex, sondern der 2. zurückgegeben werden soll, Das ist ja die Spalte, wo die Namen für die Vorlagen drin stehen. Und wie eben erwähnt, stellen wir nur noch die Funktion "T" voran, und schon sieht jetzt die Formel für VORLAGE wie folgt aus.
[code]=T(VORLAGE(SVERWEIS(A1;B3:C6;2;0)))
[/code]

Und zum Krönenden Abschluß verbinden wir jetzt die zwei seperaten Formeln miteinander, und zwar mittels "&".
[code]=SVERWEIS(A1;B3:D6;3;0)&T(VORLAGE(SVERWEIS(A1;B3:C6;2;0)))
[/code]
Und schon ist unsere "Sprechende Ampel" fertig. :D

Im Anhang ist das als Praktisches Beispiel schon fix und fertig programmiert.


Viel Spaß beim experimentieren :D
balu