oder-Abfrage mehrerer Werte

[jue]

Hallo zusammen,

ich wollte den Anfangsbuchstaben ( oder Zahl) der Spalte A , den ich mit LINKS(A) erhalte,
durch eine oder-Abfrage prüfen und dann je Bereich eine bestimmte Zahl zuweisen.

0- 9 und A- D werden zu 1
D-Z werden zu 2

Meine Formel funktioniert aber nicht.

=WENN ( ODER (LINKS(A)=ODER( 0;1;2;3;4;5;6;7;8;9;A;B;C; D ) ) ; 1; 2)

Warum geht das nicht?

Gibt es eine funktionierende Lösung (auch mit Kleinbuchstaben)?

[clag]

hallo jue,

da fällt als erstes das zweite = in der Formel auf

[bst]

Auch Hallo,

Du kannst auch reguläre Ausdrücke benutzen. Aktiviere diese unter Extras-Optionen-Berechnen und nimm für 0-9, a-d, A-D so etwas:

Code: Alles auswählen

B1: =WENN(ISTZAHL(SUCHEN("^[0-9a-dA-D]";A1));1;0)

cu, Bernd

[komma4]

Anstelle der unübersichtlichen, verschachtelten ODER-Funktionen würde ich vorschlagen, hier die Funktion VERGLEICH zu nutzen.


Schreibe Deine "Suchzeichen" (1,2,...,a,A,b,B) in einen Zellbereich, geben diesem einen Namen (Einfügen>Namen>Festlegen...>"gesucht").

Deine Formel lautet dann =WENN(ISTNV(VERGLEICH(LINKS(A2);gesucht;0));"nicht vorhanden";"gefunden")


Viel Erfolg!

[jue]

Danke für die schnellen Antworten!

Werde gleich mal loslegen.

[jue]

B1: =WENN(ISTZAHL(SUCHEN("^[0-9a-dA-D]";A1));1;0)

Funktioniert gut!

Wie muss ich die Formel erweitern, um 3 oder mehr Bereiche abzufragen?
z.B.

0-9 und a-B
c-K
l-Z

Die Erweiterung:
B1: =WENN(ISTZAHL(SUCHEN("^[0-9a-bA-B]";A1));1;0) & WENN(ISTZAHL(SUCHEN("^[c-kC-K]";A1));2;0) & WENN(ISTZAHL(SUCHEN("^[l-zL-Z]";A1));3;0)

funktioniert leider nicht. ;-(

[bst]

Hi,

versuche mal:

Code: Alles auswählen

=WENN(ISTZAHL(SUCHEN("^[0-9a-bA-B]";A1));1;0) + WENN(ISTZAHL(SUCHEN("^[c-kC-K]";A1));2;0) + WENN(ISTZAHL(SUCHEN("^[l-zL-Z]";A1));3;0)

oder - einfacher - auch:

Code: Alles auswählen

=1*ISTZAHL(SUCHEN("^[0-9a-bA-B]";A1)) + 2*ISTZAHL(SUCHEN("^[c-kC-K]";A1)) + 3*ISTZAHL(SUCHEN("^[l-zL-Z]";A1))

bzw. falls 'Dopplungen' auftreten könnten vielleicht besser:

Code: Alles auswählen

=1*ISTZAHL(SUCHEN("^[0-9a-bA-B]";A1)) + 2*ISTZAHL(SUCHEN("^[c-kC-K]";A1)) + 4*ISTZAHL(SUCHEN("^[l-zL-Z]";A1))

Als Matrix-Formel sollte auch so etwas gehen:

Code: Alles auswählen

{=VERGLEICH(1;ISTZAHL(SUCHEN({"^[0-9a-bA-B]";"^[c-kC-K]";"^[l-zL-Z]"};A1));0)}

cu, Bernd

[jue]

Bestens, funktioniert!

Danke.