Summe in Tabelle ohne negativ Zahlen

[andreasgosen]

Hallo,
wer kann mir helfen?? Arbeite an einer Übersichtstabelle wo verschiedene Werte ausgewertet werden. In der Summe einer Spalte möchte ich dann das reale Ergebnis sehen, ich habe aber auch in den einzelnen Zellen -(minus) Werte drin möchte aber nur die Werte die größer Null in der Summe zusammenfassen. Habe schon mehrere Varianten probiert aber es klappt nicht.
Danke vorab schon mal.

andreasgosen

[Karolus]

Hallo

Code: Alles auswählen

=SUMMENPRODUKT(A1:A1000>0;A1:A1000)

Code: Alles auswählen

=SUMMEWENN(A1:A1000;">0")

Karo

[andreasgosen]

Danke für die schnelle Antwort.
Ich muss aber 2 Werte berechnen der aus jeweils zwei zusammen hängende Zellen besteht. Das heißt: es sind angenommen 20 Zellwerte in einer Spalte davonn sollen jeweils Zusammen Zelle 1&2;5&6;9&10......in einem Ergebnis und die Zellen 3&4;7&8;11&12......in einem Ergebnis Zusammengefasst werden. Und das wie gesagt ohne negative Werte. Bis zu dem von Ihnen angebotenen Lösungsweg bin ich auch schon mal gewesen, ist mir aber nicht zweckdienlich.
Vielleicht haben Sie dafür auch ein Lösungsweg.

andraesgosen

[hylli]

Nunja, Du kannst natürlich mehrere SUMMENPRODUKTE oder SUMMEWENN addieren. aber ich gehe fast davon aus, dass da noch was eleganteres von Karolus kommt.

Hylli

[Karolus]

Hallo

Code: Alles auswählen

=SUMMENPRODUKT(REST(ZEILE(A1:A1000)-1;4)<2;A1:A1000>0;A1:A1000)

bzw.

Code: Alles auswählen

=SUMMENPRODUKT(REST(ZEILE(A1:A1000)-1;4)>1;A1:A1000>0;A1:A1000)

Gruß Karo

[andreasgosen]

Danke für das schnelle reagieren, aber irgendwie komme ich nicht weiter.
Ich hab mal eine Spalte als Beispiel eingefügt, also es sollen unten jeweils ein Ergebnis für die 1.2.5.6.9.10.13.14,....Zahlen und für die 3.4.7.8.11.12.....Zahlen als Ergebnis erscheinen. Die zahlen stellen in meiner Tabelle Personen da und werden aus einer soll/ist Tabelle übernommen, also darf der minus Wert nicht mitberechnet werden, da ja sonst die Anzahl der vorhandenen Personen nicht stimmt.
Irgendwie bin ich am Ende mit meinen Künsten...........Vielleicht kopierst Du mal die Zahlenreihe in eine CalcTabelle und siehst was ich meine..............Vielleicht gibt es da noch einen anderen Lösungsweg.

Danke

andreasgosen

-1
15

0
10

0
6

-1
6

1
6

0
5

1
6

1
5

0
0

0
0

0
0

0
0

0
0

0
0

[hylli]

Ersetze A1:A1000 durch den Zellbereich der addiert werden soll.

Wenn ich Karos geniale Formel richtig interpretiert habe (auch wenn ich noch nicht ganz dahintersteige!), sollte das funktionieren.

Edit:
Getestet, funktioniert perfekt!

Hylli

[andreasgosen]

Heurika ich habs............hab nun noch einige mal probiert.Ich glaube der Fehler war, das ich zwischen den Bezugszeilen noch Leerzeilen als Abstandshalter hatte, habe diese entfernt und siehe da die Formel funktioniert dank der super Hilfe.
Das hat man auch davon wenn man sich recht komplizierten Tabellen beschäftigt.

Also vielen Dank
bis zum nächsten mal...........falls ich wieder mal Hilfe brauche

andreasgosen

[Karolus]

Hallo
Du hättest die regelmässig auftauchenden Leerzeilen erwähnen sollen, die könnte man auch noch in der Formel berücksichtigen.

Gruß Karo

[andreasgosen]

Ich hät da jetzt mal noch dumme Frage, ich möchte die Formel auch in Microsoft Office 2007 verwenden, doch leider funktioniert diese dort nicht.............gibt es auch eine Lösungsweg dafür...........ich konnte die Formle zwar übernehmen aber sie rechnet dort auf null.............und das stimmt ja nicht..............
kannst du da auch helfen???????

andreasgosen

[Axel Richter]

Hallo,

ich möchte die Formel auch in Microsoft Office 2007

In MS Office werden in Summenprodukt boolesche Werte nicht als 1 bzw. 0 ein-multipliziert. Geh Mal in der Zelle mit der Formel auf [fx], dann siehst Du, dass die ersten beiden Arrays aus WAHR- und FALSCH-Werten bestehen. Dann wird versucht bspw.: WAHR * WAHR * 15 zu rechnen, was innerhalb der Matrixformen offenbar nicht 1 * 1* 15 entspricht.

Ändere die Formeln in:
=SUMMENPRODUKT((REST(ZEILE(A1:A1000)-1;4)<2)*1;(A1:A1000>0)*1;A1:A1000)
=SUMMENPRODUKT((REST(ZEILE(A1:A1000)-1;4)>1)*1;(A1:A1000>0)*1;A1:A1000)

viele Grüße

Axel

[andreasgosen]

Hallo,

vielen Dank......du hast mir sehr geholfen. Jetzte funktioniert alles so wie ich es haben wollte .

Wie gut das es solche Foren gibt wo man als Hobbyanwender hilfe findet.

Dank auch noch mal an die anderen fleißigen Helfer!!


andreasgosen