ausgefüllte Zellen automatisch suchen

[georgy]

Hallo zusammen,

ich habe eine Tabelle, in der in Spalte B ganz selten Zahlen eingetragen sind, z.B. in B3, B25, B59, B60, B134 usw. Alle anderen Zellen dieser Spalte sind leer.

Ich möchte alle solche Zellen aus Spalte B in Spalte C zusammenhängend darstellen. Im obigen Beispiel: C1=B3, C2=B25, C3=B59, C4=B60, C5=B134. Ich kann das natürlich so machen, indem ich in die Zellen in Spalte C direkt die entsprechende Zelle aus Spalte B reinschreibe, also z.B. in Zelle C5 kann ich direkt "=B134" reinschreiben.

Ich halte diese Lösung allerdings für unelegant und fehleranfällig - vor allem dann, wenn Spalte B mehrere Hundert Einträge haben kann und wenn sich die Spalte B öfters ändert. Gibt es eine Formel, mit der ich alle nicht-leeren Zellen in Spalte B der Reihe nach automatisch suchen und in Spalte C eintragen lassen kann?

Danke schonmal für Eure Tipps

[Karolus]

Hallo Georgy
Benutze eine Hilfsspalte mit der Formel:
=WENN(B1="";"";ZEILE())
Zieh die Formel soweit wie nötig nach unten.

In C1 kopierst du folgendes:

Code: Alles auswählen

 =WENN(ISTFEHL(INDIREKT("B"&KKLEINSTE(D$1:D$1000;ZEILE())));"";INDIREKT("B"&KKLEINSTE(D$1:D$1000;ZEILE())))

Die Hilfsspalte ist hier im Beispiel Spalte D, müsstest du dann evtl. anpassen.
Diese Formel ziehst du dann soweit nach unten das die maximale Anzahl an Einträgen in B mit Sicherheit erfasst wird.
Falls die Hilfsspalte optisch stört, blende sie einfach aus.

Gruß Karo

[Eia]

Kannst Du damit etwas anfangen?

tab.zip

Datei nur umbenennen nach .ods

(9.25 KiB) 108-mal heruntergeladen

[balu]

Hallo georgy,

ich habe da auch noch einen vorschlag. Dieser ist jedoch ohne Hilfsspalte.

In C1 schreibst Du

Code: Alles auswählen

=MIN(B1:B10000)

In C2 kommt dann folgende Formel

Code: Alles auswählen

=WENN(MAX($B$1:$B$10000)=MAX($C$1:C1);"";KGRÖSSTE($B$1:$B$10000;ZÄHLENWENN($B$1:B$10000;">"&C1)))

Diese kopierst Du soweit runter so lang deine B-Spalte ist. (hier als Beispiel 10000)
Hübscher nebeneffekt an dieser Formel.
Das Ergebnis ist auch gleich sortiert.

Habe das ganze auch gleich mal als Beispiel in den Anhang getan.


Gruß
balu


umbenennen in .ods

[Karolus]

Hallo Balu

Da schummelst du aber
-mit Sortierung ist das ja gaaanz einfach:
=WENN(ISTFEHL(KKLEINSTE(B$1:B$21;ZEILE()));"";KKLEINSTE(B$1:B$21;ZEILE()))

Gruß Karo

[balu]

Hallo Karo,

wer schummelt hier? Ich etwa!!??
Also das verbitte ich mir, solche Unterstellungen.
Ich habe doch nur von diesem X abgekupfert, und angepasst. Das nenn ich Diebstahl, aber nicht schummeln

Gruß
balu



p.s. Deine Formel gefällt mir besser, hab sie eben getestet