Wenn, dann, AUSSER

[eM89]

Hallo, ich habe nun seit 3 Stunden ein Problem mit einer Calc-Tabelle.
Es geht darum, dass ich automatisch berechnen lassen möchte, wann die nächste Abbuchung fällig ist, wenn sie halbjährig oder ganzjährig gebucht wird. Die addierung ob halb oder ganzjährig habe ich schon hinbekommen.
Teilweise ist jedoch noch kein Abbuchungsdatum eingetragen, dann soll "Abgebucht?" in die Zelle eingetragen werden. Wenn ganzjährig gebucht wird kriege ich das auch hin, jedoch nicht, wenn halbjährig gebucht werden soll. Meine Formel lautet momentan so:
=WENN(D11="X"; F11+182,5; +WENN(F11=0;"Abgebucht?";+WENN(E11="X";F11+182,5; F11+365)))

Wahrscheinlich findet ihr einige unsinnige Dinge darin, bin kein Profi und habe es wahrscheinlich durch Zufall geschafft das es halbwegs funktioniert^^
hier einmal die übersicht. bitte nehmt es mir nicht übel dass ich euch die Datei aus Datenschutzgründen nicht zeigen kann, wenn es nötig ist muss ich sie ganz ändern aber ich hoffe ihr schafft das auch so!

Wenn ihr noch fragen habt - PM oder Post!
Ich bin euch sehr dankbar
Lg Marcel

[lorbass]

In G2 eintragen und nach unten kopieren:

Code: Alles auswählen

=WENN(D2="X";WENN(ISTLEER(F2);"Abgebucht?";F2+182,5);(WENN(E2="X";WENN(ISTLEER(F2);"Abgebucht?";F2+365))))

Die Datumsberechnung durch Addition von 182,5 bzw. 365 Tagen kann man sicher noch verbessern, z.B.:

Code: Alles auswählen

=WENN(D2="X";WENN(ISTLEER(F2);"Abgebucht?";DATUM(JAHR(F2);MONAT(F2)+6;TAG(F2)));(WENN(E2="X";WENN(ISTLEER(F2);"Abgebucht?";DATUM(JAHR(F2)+1;MONAT(F2);TAG(F2))))))

Gruß
lorbass

[chrk]

Die Datumsberechnung durch Addition von 182,5 bzw. 365 Tagen kann man sicher noch verbessern,

Das kann man auch alles Calc und der Finanzfunktione ZINSTERMNZ() überlassen, indem man als Abrechnungstermin den Termin der Abbuchung nimmt, dem für den Fälligkeitstermin ein Jahr aufschlägt und für die Anzahl der Zinszahlungen hier Anzahl der Abbuchungen im Jahr setzt:

Code: Alles auswählen

=WENN(ISTZAHL(E2);ZINSTERMNZ(E2;DATUM(JAHR(E2)+1;MONAT(E2);TAG(E2));$D2;1);"Abgebucht?")

Das Ganze wird dann noch in eine WENN()-Funktion verpackt, die ermittelt, ob eine Zahl im Abbuchungsfeld steht.

[lorbass]

Hallo paljass,

warum sollich in der Formel zweimal fragen,ob F2 leer ist, wo doch in beiden Fällen das selbe passiert?

Stimmt!

=WENN(ISTLEER(F5);"Abgebucht?";WENN(D5="X";DATUM(JAHR(F5);MONAT(F5)+6;TAG(F5));WENN(E5="X";DATUM(JAHR(F5)+1;MONAT(F5);TAG(F5));"Zahlweise?")))

Gruß
lorbass

[Gert Seler]

Hallo Zusammen,
mit dieser Formel geht es kürzer und einfacher :

Code: Alles auswählen

=WENN($C2="";"";WENN($F2="";"Abbuchung? ? ?";WENN($D2="x";EDATUM($F2;6);WENN($E2="x";EDATUM($F2;12)))))

Die Formel "EDATUM" kann viele Berechnungen mit "DatumAngaben" erleichtern.
Formel nach unten kopieren und es hat sich.

mfg
Gert