Werte in einem Haushaltsbuch auswerten

[pinmoney]

Hallo.

Und zwar bin ich gerade dabei ein kleines Haushaltsbuch zu schreiben und habe folgendes Problem. Und zwar haben ich eine Tabelle "Januar" in der gibt man halt seine Buchnungen ein. Nun soll die Buchung ausgewertet werden und in einer Tabelle eingeordnet werden.

Kurz gesagt, habe ich eine Buchung z.B. Onlinekosten dann müßte diese in der Tabelle "Auswertung" in der Zeile Onlinekosten für den jeweiligen Monat eingetragen werden.
Könnte mir da jemand bzgl. der Formel auf die Sprünge helfen? Beim letzten Haushaltsbuch hatte ich das über "indirekt" gelöst.

Das ganze habe ich mal als Anhang dran gehangen.

Gruß Peter

[Gert Seler]

Hallo Peter,
in "Auswertung Peter" Zelle C43 folgende Formel eintragen:

Code: Alles auswählen

=SVERWEIS($A$43;Januar.D7:G56;4;0)

[/b]
Sinngemäß gilt dies für alle anderen Verwendungszwecke und "Monatsauswertungen".
Oder schau mal hier rein :
http://www.ooowiki.de/CalcFunktionenTab ... atenFinden

Sollte auch passen.

mfg
Gert

[pinmoney]

Ok, aber jetzt rechnet er mir ja nicht zusammen wenn ich im gleichen Monat 2 mal den Verwendungszweck z.B. Onlinekosten habe?

[balu]

Hallo Peter,

mir fallen gleich die Augen zu, deshalb werd ich mich kurz fassen.

Deine Beispieldatei habe ich jetzt stellenweise deinen Wünschen angepasst. Das ist im Blatt "Auswertung Peter" dadurch zu sehen, dass die betroffenen Zellen mit der Hintergrundfarbe "Blaugrau" gekenzeichnet sind.

Geändert habe ich dort auch deine SUMME, da sie eine unschöne Null (0) ausgibt, wenn kein Eintrag vorhanden ist. Jetzt steht da z.B.

Code: Alles auswählen

=WENN(ZÄHLENWENN(C5:C8;"<>");SUMME(C5:C8);"")

Es wird erst dann die Summe gebildet, wenn ZÄHLENWENN mindestens eine Zelle findet die ungleich leer ist, sonst wird gar nichts gemacht.

So, und nun die etwas längere Formel für die Auswertung.

Code: Alles auswählen

=WENN(ISTFEHLER(ZELLE("SHEET";INDIREKT(C$1&".A1")));"";WENN(ZÄHLENWENN(INDIREKT(C$1&".D7:D56");A5);SUMMENPRODUKT(INDIREKT(C$1&".D7:D56")=A5;INDIREKT(C$1&".G7:G56"))))

Grob erklärt geschieht folgendes.
Du hast ja in der Zeile 1 die Monatsnamen aufgeführt, und da ich davon ausgehe das die einzelnen Blätter den gleichen Namen haben werden, frage ich erst mal mit ISTFEHLER(ZELLE(... nach ob es dieses Tabellenblatt NICHT gibt, wenn das der Fall ist, wird nichts gemacht. Sollte das Blatt aber vorhanden sein, schaut ZÄHLENWENN erst mal nach ob in dem Blatt die aufgeführte Kategorie z.B. in A5 (KFZ Versicherung) auch aufgeführt ist. Wenn dem so ist, wird jetzt mittels SUMMENPRODUKT zusammengerechnet wie oft KFZ Versicherung vorhanden ist, und parallel dazu die Summe der einzelnen aufgeführten Kosten zu KFZ Versicherung ausgerechnet.
Und sollte ZÄHLENWENN feststellen das die Kategorie nicht aufgelistet ist, wird gar nichts gemacht. Auch hierbei wird keine Null (0) angezeigt.

Ach so ja!
Diese Formel ist so aufgebaut, dass Du sie jetzt ganz einfach nach rechts und unten kopieren kannst. Es spielt keine Rolle ob es z.B. das Blatt "November" schon gibt, oder nicht. Deswegen habe ich ja die ISTFEHLER(ZELLE(... eingebaut.

Ich hoffe, dass Du mich, und die Formel, verstehst.


Gruß
balu

[Gert Seler]

Hallo Peter,
es geht auch kürzer :

Code: Alles auswählen

=WENN(ISTFEHLER(SUMMEWENN($Januar.$D$7:$D$56;$A$2:$A$78;$Januar.$G$7:$G$56));"";SUMMEWENN($Januar.$D$7:$D$56;$A$2:$A$78;Januar.$G$7:$G$56))

Beim kopieren in die anderen "MonatsSpalten" von "Auswertung Peter" müssen hier die MonatsNamen entsprechend angepasst werden.
Der Formelaufbau ist einfacher und anhand der "Ooo_Hilfe" oder "Ooo_wiki" schnell erklärt.
Siehe: Ooo_Hilfe oder :
http://www.ooowiki.de/SummeWenn?highlight=(SUMMEWENN)

Die Formel von Balu deckt natürlich das ganze "AuswertungsSpektrum" ab und ist ideal für eine "Geschützte-Tabelle", da werden ja die "Formeln"
geschützt.

mfg
Gert

[balu]

Hallo,

@Gert

... und ist ideal für eine "Geschützte-Tabelle", da werden ja die "Formeln"
geschützt.

Versteh ich jetzt nicht ganz so recht. Is aber net schlimm.

Ja Gert, Du hast recht, dass es auch kürzer geht
Aber ich bin ein Design-Freak , der es gerne vermeiden möchte Nullwerte anzeigen zulassen. Das funktioniert bei deiner nicht so wirklich. Aber dafür kann man meine auch noch ein winzig kleines stückchen kürzen, wenn schon alle Tabellenblätter vorhanden sind. Und da war ich mir nämlich nicht so sicher, ob alle Monate in der fertigen Datei schon vorhanden sind, oder ob sie erst so nach und nach erstellt werden.

@Peter
Und!? Welche gefällt dir besser?


Grüße an alle
balu

[pinmoney]

Hallo Balu,

vielen Dank. Echt. Da hast du mir ja gleich ne Menge Arbeit abgenommen. Werd mir die Formel erstmal richtig anschauen bevor ich dahinter komme.
Ich denke aber das ist genau das was ich gesucht habe. Was ich noch gerade gesehe habe.

Wenn ich jetzt bei Einnahme was buche z.B. Lohn wird das ganze noch nicht gebucht. Reicht es da aus wenn ich deine Formel abändere?

[balu]

Hallo Peter,

Reicht es da aus wenn ich deine Formel abändere?

Ja, das reicht.
Du musst nur in der Formel die G-Adressen -{ist der letzte Formelteil}- gegen H austauschen.
Im Detail:

Code: Alles auswählen

INDIREKT(C$1&".G7:G56")

Das ist der Bereich für Ausgaben, so wie momentan gegeben.

Code: Alles auswählen

INDIREKT(C$1&".H7:H56")

Das ist der Bereich für Einnahmen, so wie Du es haben möchtest.

Alles klar?


Es freut mich, das ich dir bis jetzt helfen konnte


Gruß
balu

[pinmoney]

Ja und beide zusammen?
Einnahme und Ausgabe unterscheide ja nur ich. Zusammen gezählt soll aber in der Auswertung
beides.

[balu]

Hallo Peter,

sorry, falls ich dich etwas überfordert habe.
Die Formel die bis jetzt in der Auswertung drin ist, ist ja nur für die Ausgaben (Zeilen 5 bis 54). Und deine Einnahmen werden dort im Zeilenbereich 57 bis 78 ausgewertet. Also musst Du die Formel in C57 umschreiben (anschließend kopieren), und zwar wie folgt.

Code: Alles auswählen

=WENN(ISTFEHLER(ZELLE("SHEET";INDIREKT(C$1&".A1")));"";WENN(ZÄHLENWENN(INDIREKT(C$1&".D7:D56");$A57);SUMMENPRODUKT(INDIREKT(C$1&".D7:D56")=$A57;INDIREKT(C$1&".H7:H56"));""))

Der letzte Teil der Formel ist das, was ich vorhin erklärt habe. Hoffe das es jetzt klarer ist.

Tschulli, das dies eben nicht so deutlich rüberkam.



Gruß
balu

[pinmoney]

Gut, aber er soll mir doch Spalte G und H zusammen rechnen?
Oder hast du einen Fehler bei dir?

[pinmoney]

Ah, jetzt versteh ich wie du es meinst.

[AhQ]

Hallo miteinander,

das ist ja eine nette Formel, aber mal für die Langsamen unter uns: Was ist der Vorteil der Istfehler(Zelle(sheet...))-Konstruktion? Weil letztlich bekomm ich doch auch nur eine Fehlermeldung, wenn es das Blatt nicht gibt, oder? Da kann ich mir das doch auch sparen und gleich ISTFEHLER(INDIREKT(C$1&".A1")) schreiben. Da bekomm ich genauso eine Fehlermeldung und zumindest bei mir funktioniert es genauso. Oder überseh ich irgendwas und bei der Zelle()-Geschichte passiert was bedeutendes?

Viele Grüße
AhQ

[Karolus]

Hallo Peter
Im Layout der Monatstabellen unterscheidest du doch die "Ausgaben"spalte H und die "Einnahmenspalte" G, Balu (ich auch) geht davon aus das du zu Einnahmen(kategorien) Beträge ausschliesslich in G einträgst.
Daher müsste Balus letzte Formel für die Einnahmezeilen in der Auswertung genau passen.

@Ahq
Nee, Balus Konstrukt fängt Fehler bei nicht vorhandenen Blättern ab.

Gruß Karo

[balu]

Hallo Leute,

@Peter
Ich seh da grad eben, dass Du deine Auswertung nicht Korrekt führst. Ist wahrscheinlich nur ein flüchtigkeitsfehler .
Du hast deine Einnahmen an der Falschen Stelle plaziert, denn nach den Einnahmen stehen schon wieder Ausgaben. Und das kann ich irgendwie nicht richtig nachvollziehen. Besser wärs wenn Du die Einnahmen ganz zum schluß setzt.

@Ahq
Du hast recht, ich hatte da etwas zu kompliziert gedacht. Es reicht wirklich, wenn man deinen Vorschlag nimmt. Die abgeänderte Formel sieht dann z.B. so aus.

Code: Alles auswählen

=WENN(ISTFEHLER(INDIREKT(C$1&".A1"));"";WENN(ZÄHLENWENN(INDIREKT(C$1&".D7:D56");$A5);SUMMENPRODUKT(INDIREKT(C$1&".D7:D56")=$A5;INDIREKT(C$1&".G7:G56"));""))

Ich danke dir für den kleinen, aber nicht unbedeutenden Hinweis

@Karo
Yep, Du hast mich durchschaut


Grüße euch alle
balu