[erledigt] Zelleninhalt als Referenz abhängig von Formel

[housefreund]

Hallo,
ich habe eine Wertereihe, z.B. in den Feldern B1 bis B9. Zu jedem Wert existiert ein Datum. In den Feldern A1 bis A9.

In einem Feld weiter unten lasse ich den Maximalwert der Werterreihe via

Code: Alles auswählen

=max(b1:b9)

ausgeben. Wie kann ich in dem Feld rechts davon das zugehörige Datum aus der A-Spalte ausgeben lassen?

[clag]

Hallo housefreund

wenn der Bereich B1:B9 aufsteigend sortiert ist ginge zB VERWEIS()
wenn das Datum rechts von der Werteliste stehen würde ginge auch SVERWEIS() bei unsortierter Werteliste

hmm... für diesen konkreten Fall ist mir noch nichts eingefallen

[bst]

Morgen,

Code: Alles auswählen

C11: =VERGLEICH(B11;B1:B9;0)

sucht den Wert B11 aus B1:B9 und liefert dessen Index (Zeilennummer bezüglich des Bereiches) zurück.

Code: Alles auswählen

D11: =INDEX(A1:A9;C11;1)

liefert den zugehörigen Wert aus Spalte A.

Zusammengebaut ergibt das:

Code: Alles auswählen

C11: =INDEX(A1:A9;VERGLEICH(B11;B1:B9;0);1)

Du kannst auch gleich noch den Max dort einbauen, d.h.:

Code: Alles auswählen

C11: =INDEX(A1:A9;VERGLEICH(MAX(B1:B9);B1:B9;0);1)

cu, Bernd

[clag]

Hallo bst,

da sag ich auch mal Danke für diese "Formelkreation" weil ...

für diesen konkreten Fall ist mir noch nichts eingefallen

nun kenne ich eine gute Lösung

[housefreund]

Morgen,
Du kannst auch gleich noch den Max dort einbauen, d.h.:

Code: Alles auswählen

C11: =INDEX(A1:A9;VERGLEICH(MAX(B1:B9);B1:B9;0);1)

cu, Bernd

Hallo Bernd, vielen Dank!
Ich habe dann mal testweise

Code: Alles auswählen

C11: =INDEX(A1:A9;VERGLEICH(C10;B1:B9;0);1)

eingegeben, das geht auch. Das ist auch besser.

Ich wollte dann mal mich mehr mit der Vergleich-Funktion auseinandersetzen, habe aber dazu keine richtige Hilfe gefunden:

Aber ich habe bei Calc ohnehin noch das DAU-Gefühl manchmal.

Ich dachte halt, man könnte auch folgenden Code verwenden: (der Code ist jetzt direkt mit Bezug auf die vorhanden Zellen bei mir)

Code: Alles auswählen

=INDEX(a2:a10;max(b2:b10);1)

Aber das geht nicht. Es kommt "Err:502".

Wie müsste man denn den Code von dir anpassen, damit man das gleiche "Bezugsfeld" ausgeben kann, nur bei dem Minimalwert?
Sprich, quasi mit
b17: =min(b2:b10)
und dann
b18: =index(....)

[hylli]

Manchmal springt die Hilfe nicht immer zu 100% an die richtige Position.

Hier der Auszug aus der Hilfe:

VERGLEICH
Liefert die relative Position eines Elements in einer Matrix, das mit einem angegebenen Wert übereinstimmt. Die Funktion liefert die Position des in "Suchmatrix" gefundenen Werts in Form einer Zahl.
Syntax
VERGLEICH(Suchkriterium; Suchmatrix; Typ)
Suchkriterium ist der Wert, nach dem in der einzeiligen oder einspaltigen Matrix gesucht werden soll.
Suchmatrix ist der gesuchte Bezug. Eine Suchmatrix kann eine einzelne Zeile oder Spalte oder ein Teil einer einzelnen Zeile oder Spalte sein.
Typ kann die Werte 1, 0 oder -1 annehmen. Wenn Typ den Wert 1 hat oder dieser optionale Parameter fehlt, wird davon ausgegangen, dass die erste Spalte der Suchmatrix in aufsteigender Reihenfolge sortiert ist. Bei Typ = -1 wird von einer absteigend sortierten Spalte ausgegangen. Dies stimmt mit derselben Funktion in Microsoft Excel überein.
Wenn Typ = 0, dann werden nur exakte Übereinstimmungen gefunden. Wenn das Suchkriterium mehrmals gefunden ist, gibt die Funktion den Index des ersten übereinstimmenden Werts zurück. Sie können nur dann nach regulären Ausdrücken suchen, wenn Typ = 0.
Wenn Typ = 1 oder wenn der dritte Parameter nicht vorhanden ist, wird der Index des letzen Werts, der kleiner als das Suchkriterium oder gleichgroß ist, zurückgegeben. Dies gilt auch dann, wenn die Suchmatrix nicht sortiert ist. Bei Typ = -1 wird der erste Wert, der größer oder gleichgroß ist, zurückgegeben.
Die Suchfunktion unterstützt reguläre Ausdrücke. Sie können Sie beispielsweise mit "all.*" nach dem ersten Auftreten von "all" gefolgt von beliebigen anderen Zeichen suchen. Wenn Sie nach einem Text suchen möchten, der auch als regulärer Ausdruck verwendet wird, müssen Sie jedem Zeichen ein "\"-Zeichen voranstellen. Unter Extras – Optionen – OpenOffice.org Calc – Berechnen können Sie die automatische Auswertung eines regulären Ausdrucks ein- bzw. ausschalten.
Beispiel
v=VERGLEICH(200;D1:D100) durchsucht den Bereich D1:D100, der durch Spalte D sortiert wird, nach dem Wert 200. Sobald dieser Wert gefunden ist, wird die Nummer der Zeile, in der der Wert gefunden wurde, zurückgegeben. Wenn beim Suchen in der Spalte ein höherer Wert gefunden wird, wird die Nummer der vorhergehenden Zeile zurückgegeben.
VERSCHIEBUNG

Hylli

[housefreund]

Danke, hylli. Das wird wohl einen Fehler von vorhin erklären, den ich hatte. Die Funktion VERGLEICH scheint auf sortierten Werten zu basieren. Meine Wertereihe ist unsortiert und wird auch nicht sortiert. Es liegt ein chronologischer Bezug vor. Spalte A sind Daten. Die Spalten B bis D enthalten abgelesene Werte.

[bst]

Auch nochmals Hallo,

mit MAX(Bereich) bekommst Du den maximalen Wert selber zurück, für INDEX benötigst Du aber dessen Adresse in Form von Zeilen- und Spalten-Nummer.

VERGLEICH kommt sowohl mit sortierten als auch mit unsortierten Bereichen zurecht, dafür existiert der letzte Parameter Typ.

Wichtig ist dass VERGLEICH nur in einem eindimensionalen Bereich funktioniert, also in einer Spalte oder in einer Zeile.

Beispiel, Daten in B10:B20, das eindeutige Maximum sei in B13.

Code: Alles auswählen

C10: =MAX(B10:B20) 

liefert den Wert aus B13,

Code: Alles auswählen

D10: =VERGLEICH(C10;B10:B20;0) 

liefert hier 4. Da B13 die 4. Zeile im Bereich B10:B20 ist.

Code: Alles auswählen

E10: =INDEX(A10:A20;D10;1) 

liefert den Wert aus A13, da D10 = 4 und A13 die 4. Zeile im Bereich A10:A20 ist.

Jetzt klarer?

Bernd

[Karolus]

Hallo
@Housefreund
Die Funktion VERGLEICH benötigt nicht zwingend sortierte Bereiche, du musst lediglich den dritten Parameter auf 'falsch' oder 0 setzen.
Das hat Bernd alias bst übrigens schon in seinen Formeln eingebaut, liest du eigentlich die Antworten die du bekommst ??

Karo

[housefreund]

Auch nochmals Hallo,

[...]

[...]

liefert den Wert aus A13, da D10 = 4 und A13 die 4. Zeile im Bereich A10:A20 ist.

Jetzt klarer?

Bernd

Vielen Dank für die ausführliche Erläuterung. Es ist jetzt klarer. Es ist ein bisschen verschachtelt und kompliziert für mich, aber ich kann eine Art "Regel" erkennen, ich habe es nachvollziehen können.